登录
当前位置： 首页 > 文档资料 > NSIS 图文教程集锦 >

脚本：迅雷5.8.4.572 去广告 Full_组件选装版

优质
小牛编辑
121浏览
2023-12-01
引用脚本的内容：

!define SSXF    ;盛世雄风标志及其它格式模式
!define _MAX_SEL_
!define FULL
;!define SVCPACK

;
;  转载请保留：
;  原创：muniao， bbs.ssxf.org
;  2008-08-21
;
;  开源的意思是：
;  我核对了17个迅雷组件的，免得大家做重复工作。
;
!define SNAME `Thunder`
!define PRODUCT_VERSION `5.8.4.572`
!ifdef FULL
    !define PRODUCT_NAME `迅雷Ayu去广告版`
    !define EXEFN `迅雷_${PRODUCT_VERSION}_Full.exe`
!else
    !define PRODUCT_NAME `迅雷Ayu去广告精简版`
    !define EXEFN `迅雷_${PRODUCT_VERSION}_Lite.exe`
!endif
;
SetCompressor /SOLID lzma
SetCompressorDictSize 16
;
!include `MUI2.nsh`
!include `xtlib.nsh`
!packhdr temp.dat 'upx -9 -q temp.dat'
;===========================================================================================
!define MUI_HEADERIMAGE
!define MUI_HEADERIMAGE_BITMAP `_OTH\setup11.bmp`
!undef  MUI_WELCOMEFINISHPAGE_BITMAP
!define MUI_WELCOMEFINISHPAGE_BITMAP `_OTH\logor11.bmp`
!define MUI_FINISHPAGE_RUN `$INSTDIR\${SNAME}.exe`
;===========================================================================================
!macro INST_PLUGIN _DIR1 _DIR2
    !ifdef FULL
        SetOutPath `$INSTDIR\${_DIR1}`
        File /r `${PRODUCT_VERSION}\${_DIR1}\${_DIR2}`
    !else
        SectionIn RO
    !endif
!macroend
;===========================================================================================
!macro INST_FUNC_FILE _DIR _FN
    !ifdef FULL
        SetOutPath `$INSTDIR\${_DIR}`
        File `${PRODUCT_VERSION}\${_DIR}\${_FN}`
    !else
        SectionIn RO
    !endif
!macroend
ComponentText `在精简版中部分组件为不可选状态。要安装这些组件，请到 ${COMPNAME} 下载完整版。`
;===========================================================================================
!undef  MUI_ICON
!define MUI_ICON `_Oth\thunder.ico`
!undef  MUI_UNWELCOMEFINISHPAGE_BITMAP
!define MUI_UNWELCOMEFINISHPAGE_BITMAP `_Oth\WizardImage.bmp`
;===========================================================================================
!define MUI_UNINSTALLER
!ifndef SVCPACK
    !insertmacro MUI_PAGE_WELCOME
    !insertmacro MUI_PAGE_COMPONENTS
    !insertmacro MUI_PAGE_DIRECTORY
!else
    !undef EXEFN
    !define EXEFN `THUNDER5.EXE`
!endif
!insertmacro MUI_PAGE_INSTFILES
!ifndef SVCPACK
    !insertmacro MUI_PAGE_FINISH
!endif
    !insertmacro MUI_UNPAGE_CONFIRM
    !insertmacro MUI_UNPAGE_INSTFILES
;
!insertmacro MUI_LANGUAGE `SimpChinese`
SetFont /LANG=`${LANG_SimpChinese}` `宋体` 11
!insertmacro FORE_EXEINFO
;
InstallDir `$PROGRAMFILES\Thunder Network\${SNAME}`
InstallDirRegKey HKLM `Software\Microsoft\Windows\CurrentVersion\Uninstall\${SNAME}` `InstallLocation`
SetOverwrite try
;===========================================================================================
Section `${PRODUCT_NAME}`
    SectionIn RO
    SetOutPath `$INSTDIR`
    SetOverwrite try
        File /r `${PRODUCT_VERSION}\Languages`
        File /r `${PRODUCT_VERSION}\Profiles`
        File /r /x LiveUpdate.dll `${PRODUCT_VERSION}\Program`
        File `${PRODUCT_VERSION}\Thunder.exe`
    SetOutPath `$INSTDIR\Profiles`
        File `/oname=UserConfig.ini` `${PRODUCT_VERSION}\Profiles\AyuConfig.ini`
        CreateDirectory `$INSTDIR\Components`
        CreateDirectory `$INSTDIR\Plugins`
        CreateDirectory `$INSTDIR\ComDlls`
    SetOutPath `$INSTDIR`
    CreateShortCut `$SMPROGRAMS\迅雷.lnk` `$INSTDIR\Thunder.exe`
SectionEnd
;===========================================================================================
SectionGroup `浏览器右键支持 / BHO 插件`
    Section `支持右键下载`
        SetOutPath `$INSTDIR\ComDlls`
        File `${PRODUCT_VERSION}\ComDlls\ThunderAgent.dll`
        RegDLL ThunderAgent.dll
WriteRegStr   HKLM `SOFTWARE\Thunder Network\ThunderOem\thunder_backwnd` `Cache` `$APPDATA\vod_cache_data\`
WriteRegStr   HKLM `SOFTWARE\Thunder Network\ThunderOem\thunder_backwnd` `Path` `$INSTDIR\Thunder.exe`
WriteRegStr   HKLM `SOFTWARE\Thunder Network\ThunderOem\thunder_backwnd` `Version` `${PRODUCT_VERSION}`
WriteRegStr   HKCU `Software\Microsoft\Internet Explorer\MenuExt\使用迅雷下载` `` `$INSTDIR\Program\geturl.htm`
WriteRegDWORD HKCU `Software\Microsoft\Internet Explorer\MenuExt\使用迅雷下载` `Contexts` 0x00000022
;WriteRegStr   HKCU `Software\Microsoft\Internet Explorer\MenuExt\使用迅雷下载全部链接` `` `$INSTDIR\Program\getallurl.htm`
;WriteRegDWORD HKCU `Software\Microsoft\Internet Explorer\MenuExt\使用迅雷下载全部链接` `Contexts` 0x000000f3
    SectionEnd
    Section /o `浏览器工具栏 / BHO 插件`
        !insertmacro INST_PLUGIN `` `ComDlls`
        SetOutPath `$INSTDIR\ComDlls`
        RegDLL ThunderAgent.dll
/*
WriteRegStr   HKLM `SOFTWARE\Microsoft\Internet Explorer\Extensions\{09BA8F6D-CB54-424B-839C-C2A6C8E6B436}` `ButtonText` `迅雷5`
WriteRegStr   HKLM `SOFTWARE\Microsoft\Internet Explorer\Extensions\{09BA8F6D-CB54-424B-839C-C2A6C8E6B436}` `Exec` `$INSTDIR\Thunder.exe`
WriteRegStr   HKLM `SOFTWARE\Microsoft\Internet Explorer\Extensions\{09BA8F6D-CB54-424B-839C-C2A6C8E6B436}` `Icon` `$INSTDIR\Program\Thunder.ico`
WriteRegStr   HKLM `SOFTWARE\Microsoft\Internet Explorer\Extensions\{09BA8F6D-CB54-424B-839C-C2A6C8E6B436}` `HotIcon` `$INSTDIR\Program\Thunder.ico`
WriteRegStr   HKLM `SOFTWARE\Microsoft\Internet Explorer\Extensions\{09BA8F6D-CB54-424B-839C-C2A6C8E6B436}` `MenuStatusBar` `迅雷5`
WriteRegStr   HKLM `SOFTWARE\Microsoft\Internet Explorer\Extensions\{09BA8F6D-CB54-424B-839C-C2A6C8E6B436}` `MenuText` `迅雷5`
WriteRegStr   HKLM `SOFTWARE\Microsoft\Internet Explorer\Extensions\{09BA8F6D-CB54-424B-839C-C2A6C8E6B436}` `CLSID` `{1FBA04EE-3024-11D2-8F1F-0000F87ABD16}`
WriteRegStr   HKLM `SOFTWARE\Microsoft\Internet Explorer\Extensions\{09BA8F6D-CB54-424B-839C-C2A6C8E6B436}` `Default Visible` `Yes`
*/
    SectionEnd
SectionGroupEnd
;===========================================================================================
Section /o `自动更新`
    !insertmacro INST_FUNC_FILE `Program` `LiveUpdate.dll`
SectionEnd
Section /o `可选皮肤`
    !insertmacro INST_PLUGIN `` `Skins`
SectionEnd
Section /o `VC 运行库`
    SetOverwrite try
    !ifdef FULL
        SetOutPath `$SYSDIR`
        File `_Oth\msvcp60.dll`
        File `_Oth\msvcp71.dll`
        File `_Oth\msvcr71.dll`
    !else
        SectionIn RO
    !endif
SectionEnd
;===========================================================================================
SectionGroup `可选组件和插件`
    Section /o `聊天功能`
        !insertmacro INST_PLUGIN `Components` `Community`
    SectionEnd
    Section /o `视频信息预览/边下边看`
        !insertmacro INST_PLUGIN `Components` `DownAndPlay`
        SetOutPath `$INSTDIR\Components\DownAndPlay`
        RegDLL `$INSTDIR\Components\DownAndPlay\DapPlayer.dll`
        RegDLL `$INSTDIR\Components\DownAndPlay\xlsf.dll`
        RegDLL `$INSTDIR\Components\DownAndPlay\DapCtrl.dll`
    SectionEnd
    Section /o `下载纠错插件`
        !insertmacro INST_PLUGIN `Components` `DownloadStat`
    SectionEnd
    Section /o `多浏览器支持插件`
        !insertmacro INST_PLUGIN `Components` `ExplorerHelper`
    SectionEnd
    Section /o `迅雷看看`
        !insertmacro INST_PLUGIN `Components` `KanKan`
        !insertmacro INST_PLUGIN `Plugins` `KanKanTop`
        SetOutPath `$INSTDIR\Components\KanKan`
            RegDLL `$INSTDIR\Components\KanKan\XAFilter.ax`
            RegDLL `$INSTDIR\Components\KanKan\PPlayer.dll`
            RegDLL `$INSTDIR\Components\KanKan\Xdrm.dll`
            RegDLL `$INSTDIR\Components\KanKan\XmvSource.dll`
            RegDLL `$INSTDIR\Components\KanKan\XPlayer.dll`
            ExecWait `"$INSTDIR\Program\Thunder5.exe" /Installaddin:{EBDF4650-539A-4CC5-B6F2-B7C5E5D59735}|迅雷看看|..\Plugins\KanKanTop\KanKanTop.dll`
    SectionEnd
    Section /o `迅雷 P4P`
        !insertmacro INST_PLUGIN `Components` `P4PClient`
    SectionEnd
    Section /o `迅雷热门资源搜索/推荐`
        !insertmacro INST_PLUGIN `Components` `Search`
    SectionEnd
    Section /o `安全下载`
        !insertmacro INST_PLUGIN `Components` `Security`
        SetOutPath `$INSTDIR\Program`
        Exec `"$INSTDIR\Program\Thunder5.exe" /installaddin:{76F61D18-C813-432E-BC7A-A41A45D04113}|迅雷安全下载组件|..\Components\security\ThunderSafe.dll`
          
    SectionEnd
    Section /o `迅雷资讯`
        !insertmacro INST_PLUGIN `Components` `Tips`
    SectionEnd
    Section /o `装机必备软件`
        !insertmacro INST_PLUGIN `Components` `XLSoftBase`
    SectionEnd
    Section /o `狗狗搜索排行`
        !insertmacro INST_PLUGIN `Plugins` `GouGouTop`
        ExecWait `"$INSTDIR\Program\Thunder5.exe" /Installaddin:{1FC7CAC6-2DA8-4cb0-B440-C069956CC0CA}|狗狗搜索排行|..\Plugins\GouGouTop\GouGouTop.dll`
    SectionEnd
    Section /o `迅雷安全中心`
        !insertmacro INST_PLUGIN `Plugins` `XLSafeHost`
    SectionEnd
    Section /o `InMedia 超清晰视频广告`
        !insertmacro INST_PLUGIN `Components` `InMedia`
    SectionEnd
    Section /o `未知模块：ResWorker`
        !insertmacro INST_PLUGIN `Components` `ResWorker`
    SectionEnd
    Section /o `未知模块：VPShell`
        !insertmacro INST_PLUGIN `Components` `VPShell`
    SectionEnd
    Section /o `未知模块：UserExperience`
        !insertmacro INST_PLUGIN `Components` `UserExperience`
    SectionEnd
SectionGroupEnd
;=====================================================================================
SectionGroup `优化设置`
    Section `启用专用链支持`
        SetOutPath `$INSTDIR\ComDlls`
        File `${PRODUCT_VERSION}\ComDlls\LinkSimulate.dll`
        RegDLL `LinkSimulate.dll`
    SectionEnd
    Section `禁止偷偷上传`
        SetDetailsPrint ${DISPSUM}
        SetFileAttributes `$SYSDIR\cid_store.dat` 0
        Delete `$SYSDIR\cid_store.dat\noupload`
        CreateDirectory `$SYSDIR\cid_store.dat\noupload`
        SetFileAttributes `$INSTDIR\Program\cid_store.dat` 0
        Delete `$INSTDIR\Program\cid_store.dat\noupload`
        CreateDirectory `$INSTDIR\Program\cid_store.dat\noupload`
        SetDetailsPrint both
    SectionEnd
    Section /o `运行 Ayu设置工具手工设置`
        !insertmacro INST_FUNC_FILE `` `AyuConfig.exe`
    SectionEnd
SectionGroupEnd
;===========================================================================================
Section `创建卸载程序`
    !insertmacro SSXF_UNINSTALL `${SNAME}` `${PRODUCT_NAME}`
SectionEnd
;===========================================================================================
Section `Uninstall`
    SetDetailsPrint both
    SetDetailsView show
    DeleteRegKey HKLM `Software\Microsoft\Windows\CurrentVersion\Uninstall\${SNAME}`
    !insertmacro _DELMENU_LNK_ `迅雷`
    ExecWait  '`$INSTDIR\Program\SetupHelper.exe` /exit_thunder5'
    ExecWait  '`$INSTDIR\Program\SetupHelper.exe` /delete_bho'
    ExecWait  '`$INSTDIR\Program\SetupHelper.exe` /close_firewall'
    ExecWait  '`$INSTDIR\Program\LanguageSetter.exe` fromfile|-1'
    UnRegDLL `$INSTDIR\Components\KanKan\XAFilter.ax`
    UnRegDLL `$INSTDIR\Components\KanKan\PPlayer.dll`
    UnRegDLL `$INSTDIR\Components\KanKan\Xdrm.dll`
    UnRegDLL `$INSTDIR\Components\KanKan\XmvSource.dll`
    UnRegDLL `$INSTDIR\Components\KanKan\XPlayer.dll`
    UnRegDLL `$INSTDIR\Components\DownAndPlay\DapPlayer.dll`
    UnRegDLL `$INSTDIR\Components\DownAndPlay\xlsf.dll`
    UnRegDLL `$INSTDIR\Components\DownAndPlay\DapCtrl.dll`
    UnRegDLL `$INSTDIR\ComDlls\TDAtOnce.dll`
    UnRegDLL `$INSTDIR\ComDlls\ThunderAgent.dll`
    UnRegDLL `$INSTDIR\ComDlls\XunLeiBHO.dll`
    Delete `$INSTDIR\Thunder.exe`
    Delete `$DESKTOP\迅雷5.lnk`
    Delete `$SMPROGRAMS\迅雷\迅雷5 卸载.lnk`
    Delete `$SMPROGRAMS\迅雷\迅雷5.lnk`
    RMDir /r  `$SMPROGRAMS\迅雷`
    RMDir /r  `$INSTDIR\Skins`
    RMDir /r  `$INSTDIR\Languages`
    RMDir /r /REBOOTOK `$INSTDIR\TDTmp`
    RMDir /r /REBOOTOK `$INSTDIR\Program`
    RMDir /r /REBOOTOK `$INSTDIR\Components`
    RMDir /r /REBOOTOK `$INSTDIR\ComDlls`
    RMDir /r /REBOOTOK `$INSTDIR\Plugins`
    RMDir /r /REBOOTOK `$INSTDIR\Profiles`
    DeleteRegKey HKLM `Software\Microsoft\Windows\CurrentVersion\App Paths\Thunder.exe`
    DeleteRegKey HKCR `bittorrent\shell\open\command`
    DeleteRegKey HKCR `bittorrent\shell\open`
    DeleteRegKey HKCR `bittorrent\shell`
    DeleteRegKey HKCR `bittorrent\DefaultIcon`
    DeleteRegKey HKCR `bittorrent`
    DeleteRegKey HKCU `Software\Microsoft\Internet Explorer\MenuExt\使用迅雷下载全部链接`
    DeleteRegKey HKCU `Software\Microsoft\Internet Explorer\MenuExt\使用迅雷下载`
    DeleteRegKey HKLM `SOFTWARE\Thunder Network\ThunderOem\thunder_backwnd`
    DeleteRegKey HKLM `SOFTWARE\Thunder Network\ThunderOem`
    DeleteRegKey HKLM `SOFTWARE\Thunder Network`
    System::Call 'shell32.dll::SHChangeNotify(i, i, i, i) v (0x08000000, 0, 0, 0)'
    Delete `$INSTDIR\卸载 ${PRODUCT_NAME}.exe`
    RMDir /REBOOTOK `$INSTDIR`
    HideWindow
    MessageBox MB_ICONINFORMATION|MB_OK `${PRODUCT_NAME} 卸载完成。$\r$\r有些内容不能被删除。您可以手工删除它们。`
    SetAutoClose true
SectionEnd
;===========================================================================================
Section -Post
SetAutoClose true
SectionEnd
;===========================================================================================

免责声明： 以上内容版权归原作者所有，如有侵犯您的原创版权请告知，我们将尽快删除相关内容。感谢每一位辛勤著写的作者，感谢每一位的分享。
@小牛知识库 xnip.cn