脚本：eBook Workshop v1.5简体中文增强版

优质
小牛编辑
135浏览
2023-12-01
把我写的eBook Workshop v1.5简体中文增强版打包脚本贴出来给大家作个参考吧。
基于此文档体积的考虑，附件里的源文件是空的，但不影响编译。如果你对我这个版本感兴趣，请到轻狂志下载eBook Workshop v1.5简体中文增强版安装后复制出源文件放到相应目录下就可以编译了。
;增加一个包含链接内容的7z压缩包到可执行文件头部，使7-Zip打开看不到其他内容。
!packhdr temp.dat 'cmd /c Copy /B temp.dat /B +轻狂志.7z temp.dat'

; 安装程序初始定义常量
!define PRODUCT_NAME "eBook Workshop"
!define PRODUCT_VERSION "v1.5简体中文增强版"
!define PRODUCT_PUBLISHER "轻狂志"
!define PRODUCT_WEB_SITE "http://www.flighty.cn"
!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
!define PRODUCT_UNINST_ROOT_KEY "HKLM"

SetCompressor lzma

; ------ MUI 现代界面定义 (1.67 版本以上兼容) ------
!include "MUI.nsh"

; MUI 预定义常量
!define MUI_ABORTWARNING
!define MUI_CUSTOMFUNCTION_GUIINIT onGUIInit
!define MUI_HEADERIMAGE
!define MUI_HEADERIMAGE_RIGHT
!define MUI_HEADERIMAGE_BITMAP "top.bmp"
!define MUI_PAGE_HEADER_TEXT "最终用户许可协议"
!define MUI_PAGE_HEADER_SUBTEXT "您必须接受此协议才能继续安装！"
!define MUI_LICENSEPAGE_TEXT_TOP "要阅读协议的其余部分请按 PgDn键 往下翻页。"
!define MUI_LICENSEPAGE_TEXT_BOTTOM "如果你已经仔细阅读了许可协议，点击 下一步(N) > 继续安装。"
!define MUI_LICENSEPAGE_BUTTON "下一步(&N) >"
!define MUI_ICON "eBook Workshop.ico"
!define MUI_UNICON "eBook Workshop.ico"
!define MUI_WELCOMEFINISHPAGE_BITMAP "eBook Workshop.bmp"
!define MUI_WELCOMEPAGE_TITLE "\r\n　 eBook Workshop v1.5安装向导"
!define MUI_WELCOMEPAGE_TEXT "\r\n    eBook Workshop(E书工场)是将 HTML 页面文件、图片、Flash等捆绑成 EXE 电子文档的制作软件。\r\n\r\n    相比原程序，本安装包主要进行了以下增强：\r\n    1、更换两套更为美观的E书工具栏图标，使用时更改安装目录下的Buttons文件夹即可；2、新增239个图标，分别位于Icon 2、Icon 3、Icon 4 这个3个文件夹内；3、集成了多个精美的E书主题界面，安装即可使用。4、安装过程中可以自动注册软件为正式版本，无任何功能限制。\r\n\r\n    $_CLICK"
!define MUI_FINISHPAGE_RUN_TEXT "运行 eBook Workshop"
!define MUI_FINISHPAGE_SHOWREADME_TEXT "查看 安装说明"

; 欢迎页面
!insertmacro MUI_PAGE_WELCOME
; 许可协议页面
!insertmacro MUI_PAGE_LICENSE "许可协议.rtf"
; 组件选择页面
!insertmacro MUI_PAGE_COMPONENTS
; 安装目录选择页面
!insertmacro MUI_PAGE_DIRECTORY
; 安装过程页面
!insertmacro MUI_PAGE_INSTFILES
; 安装完成页面
!define MUI_FINISHPAGE_RUN "$INSTDIR\MAKER.exe"
!define MUI_FINISHPAGE_SHOWREADME "$INSTDIR\说明.txt"
!insertmacro MUI_PAGE_FINISH

; 安装卸载过程页面
!insertmacro MUI_UNPAGE_INSTFILES

; 安装界面包含的语言设置
!insertmacro MUI_LANGUAGE "SimpChinese"

; 安装预释放文件
!insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
; ------ MUI 现代界面定义结束 ------

Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
OutFile "Setup.exe"
InstallDir "$PROGRAMFILES\eBook Workshop"
;读取注册中的键值，如果没有，就按默认路径。
InstallDirRegKey HKCU "Software\eBook Workshop" ""
ShowInstDetails show
ShowUnInstDetails show
BrandingText "轻狂志www.flighty.cn"

Section "主程序" SEC01
  SectionIn RO
  SetOutPath "$INSTDIR"
  SetOverwrite ifnewer
  File /r "eBook Workshop\主程序\*.*"
  CreateDirectory "$SMPROGRAMS\eBook Workshop"
  CreateShortCut "$SMPROGRAMS\eBook Workshop\eBook Workshop.lnk" "$INSTDIR\MAKER.exe"
  CreateShortCut "$DESKTOP\eBook Workshop.lnk" "$INSTDIR\MAKER.exe"
SectionEnd

Section "主题风格" SEC02
  SetOutPath "$INSTDIR\Themes"
  File /r "eBook Workshop\Themes\*.*"
SectionEnd

Section "按钮图标" SEC03
  SetOutPath "$INSTDIR"
  File /r "eBook Workshop\按钮图标\*.*"
SectionEnd

Section -AdditionalIcons
  WriteIniStr "$INSTDIR\轻狂志.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
  CreateShortCut "$SMPROGRAMS\eBook Workshop\轻狂志.lnk" "$INSTDIR\轻狂志.url"
  CreateShortCut "$SMPROGRAMS\eBook Workshop\卸载程序.lnk" "$INSTDIR\uninst.exe"
SectionEnd

Section -Post
  WriteUninstaller "$INSTDIR\uninst.exe"
  WriteRegStr HKCU "Software\eBook Workshop" "" $INSTDIR
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"

	WriteRegStr HKCU "Software\Ada99\eBook Workshop" "AdaName" "QVNXb3Jk"
	WriteRegStr HKCU "Software\Ada99\eBook Workshop" "AdaKey" "NzE5RkJGNzEtMzUzQjQzNDQtQjcwQ0IxQTk="
	WriteRegDWORD HKCU "Software\Ada99\eBook Workshop" "Language" 0x000003a8
SectionEnd

#-- 根据 NSIS 脚本编辑规则，所有 Function 区段必须放置在 Section 区段之后编写，以避免安装程序出现未可预知的问题。--#

; 区段组件描述
!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC01} "将 HTML 页面文件、图片、Flash等捆绑成 EXE 电子文档的制作软件。"
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC02} "多个精美的E书主题界面，安装即可使用。"
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC03} "二百多个图标，分别位于Icon 2、Icon 3、Icon 4 这个3个文件夹内。"
!insertmacro MUI_FUNCTION_DESCRIPTION_END

/******************************
 *  以下是安装程序的卸载部分  *
 ******************************/

Section Uninstall
  Delete "$INSTDIR\*.*"

  Delete "$SMPROGRAMS\eBook Workshop\*.lnk"
  Delete "$DESKTOP\eBook Workshop.lnk"

  RMDir "$SMPROGRAMS\eBook Workshop"

  RMDir /r "$INSTDIR\Themes\银色苹果"
  RMDir /r "$INSTDIR\Themes\新奇前卫"
  RMDir /r "$INSTDIR\Themes\前卫幻想深绿色"
  RMDir /r "$INSTDIR\Themes\前卫幻想绿色"
  RMDir /r "$INSTDIR\Themes\前卫幻想蓝色"
  RMDir /r "$INSTDIR\Themes\灵界军团"
  RMDir /r "$INSTDIR\Themes\蓝色妖姬v2005"
  RMDir /r "$INSTDIR\Themes\蓝色妖姬"
  RMDir /r "$INSTDIR\Themes\蓝色心情"
  RMDir /r "$INSTDIR\Themes\金属时代"
  RMDir /r "$INSTDIR\Themes\简约之美"
  RMDir /r "$INSTDIR\Themes\黄色之旅"
  RMDir /r "$INSTDIR\Themes\黄昏幻想"
  RMDir /r "$INSTDIR\Themes\海洋之心v2005"
  RMDir /r "$INSTDIR\Themes\海洋之心"
  RMDir /r "$INSTDIR\Themes\古色古香"
  RMDir /r "$INSTDIR\Themes\半成卷轴"
  RMDir /r "$INSTDIR\Themes\Wood"
  RMDir /r "$INSTDIR\Themes\WinXP"
  RMDir /r "$INSTDIR\Themes\Water"
  RMDir /r "$INSTDIR\Themes\ThemeXP"
  RMDir /r "$INSTDIR\Themes\POPO2004_3"
  RMDir /r "$INSTDIR\Themes\POPO2004_2"
  RMDir /r "$INSTDIR\Themes\POPO2004"
  RMDir /r "$INSTDIR\Themes\Ocean"
  RMDir /r "$INSTDIR\Themes\Notepad"
  RMDir /r "$INSTDIR\Themes\New-Royale"
  RMDir /r "$INSTDIR\Themes\New-PantherS"
  RMDir /r "$INSTDIR\Themes\New-Mento"
  RMDir /r "$INSTDIR\Themes\New-Element"
  RMDir /r "$INSTDIR\Themes\New-Dogmax"
  RMDir /r "$INSTDIR\Themes\Mustang"
  RMDir /r "$INSTDIR\Themes\Metal"
  RMDir /r "$INSTDIR\Themes\MacOSX"
  RMDir /r "$INSTDIR\Themes\Love"
  RMDir /r "$INSTDIR\Themes\G-star"
  RMDir /r "$INSTDIR\Themes\GreenWinXP"
  RMDir /r "$INSTDIR\Themes\ExoBUD MP"
  RMDir /r "$INSTDIR\Themes\BlueWinXP"
  RMDir /r "$INSTDIR\Themes\BlueLove"
  RMDir /r "$INSTDIR\Themes\Apple"
  RMDir /r "$INSTDIR\LANGUAGE"
  RMDir /r "$INSTDIR\Buttons"
  RMDir /r "$INSTDIR\Buttons 2"
  RMDir /r "$INSTDIR\Icon"
  RMDir /r "$INSTDIR\Icon 4"
  RMDir /r "$INSTDIR\Icon 3"
  RMDir /r "$INSTDIR\Icon 2"
  
  RMDir "$INSTDIR\Themes"

  RMDir "$INSTDIR"
  
  ;卸载注册表中的软件注册键值
  DeleteRegKey /ifempty HKCU "Software\Ada99\eBook Workshop"
  ;卸载注册表中安装路径的键值
  DeleteRegKey /ifempty HKCU "Software\eBook Workshop"
  DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
  SetAutoClose true
SectionEnd

#-- 根据 NSIS 脚本编辑规则，所有 Function 区段必须放置在 Section 区段之后编写，以避免安装程序出现未可预知的问题。--#

Function onGUIInit
   BrandingURL::Set /NOUNLOAD "200" "0" "0" "http://www.flighty.cn"
FunctionEnd

Function .onGUIEnd
BrandingURL::Unload
FunctionEnd

Function un.onInit
  MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "您确实要完全移除 $(^Name) ，及其所有的组件？" IDYES +2
  Abort
FunctionEnd

Function un.onUninstSuccess
  HideWindow
  MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) 已成功地从您的计算机移除。"
FunctionEnd
打包用到的资源文件，点击另存。