Mandelbrot集合中的形状

Question

迷人可爱的Mandelbrot集箍和卷曲是浮点计算不准确的结果吗？

我编写了各种Mandelbrot集实现，例如动态缩放和回放。一些使用定点算法，另一些使用FPU。

我见过这个问题，它表明每一个芽都是数学上光滑的形状，周围有较小的芽。

海马形状等的游行是计算机浮点运算局限性的副作用，而不是实际的曼德布罗特集吗？

海马？由Spektre添加：

我一直想说的是，浮点运算，无论是定点运算还是固定意义运算，都不能保持迭代步骤的真实结果。Mandelbrot集有趣的部分在边界附近，在这个区域，迭代坐标可以在最终“逃逸”之前在循环的近重复中抖动数千次。

我的问题是：算术失败到导致模式吗？据我所知，完美的Mandelbrot套装实际上是围绕其他芽排列的光滑形状的芽，无穷无尽。评论者说，算术越好，著名的海马等形状越好，这可以在糟糕的实现产生模糊的图像时看到。但这只会强化我的问题：算术越精确，算术就越精确和有规律地失败，直到随着坐标的变化，出现不连续性，并以稍微不同的方式发展到失败。

不管怎样，这里有一个C函数，它使用x87 FPU迭代一个点。这段代码不是最近的，通过利用方块之间的差异，还有改进的余地，这仍然在我古老的“待办事项”列表上。

int MAXRAD = 4;
int K_LIMIT = 5000;
double REAL8, IMAG8;

int iterate (void)
// calculate Mandelbrot iterations of REAL8, IMAG8
// return iterations
{
int iters;

    __asm {

        FILD    DWORD PTR MAXRAD       ;MAX R^2
        FLD     QWORD PTR IMAG8        ;INIT Y VALUE
        FLD     QWORD PTR REAL8        ;INIT X VALUE

        FLD     ST(1)     ;WORKING Y = IMAG
        FLD     ST(1)     ;WORKING X = REAL

        MOV     ECX,DWORD PTR K_LIMIT
        MOV     BX,0100h  ;MASK FOR C0 FLAG

        ALIGN 4
    MLOOPB:               ;ITERATE      ST0  ST1  ST2  ST3  ST4  ST5  ST6  ST7
                          ;             X    Y    REAL IMAG 4.0
        FLD     ST(0)     ;PUSH X       X    X    Y    REAL IMAG 4.0
        FMUL    ST(1),ST  ;X * X        X    X^2  Y    REAL IMAG 4.0
        FMUL    ST,ST(2)  ;X * Y        XY   X^2  Y    REAL IMAG 4.0
        FADD    ST,ST(0)  ;2 * XY       2XY  X^2  Y    REAL IMAG 4.0
        FADD    ST,ST(4)  ;2XY+IMAG     Y'   X^2  Y    REAL IMAG 4.0
        FXCH    ST(2)     ;Y', Y        Y    X^2  Y'   REAL IMAG 4.0
        FMUL    ST,ST(0)  ;Y * Y        Y^2  X^2  Y'   REAL IMAG 4.0
        FLD     ST(0)     ;PUSH Y^2     Y^2  Y^2  X^2  Y'   REAL IMAG 4.0
        FADD    ST,ST(2)  ;Y^2 + X^2    R^2  Y^2  X^2  Y'   REAL IMAG 4.0
        FCOMP   ST(6)     ;TEST & POP   Y^2  X^2  Y'   REAL IMAG 4.0
        FNSTSW  AX        ;STATUS
        FSUB              ;X^2 - Y^2    ...  Y'   REAL IMAG 4.0
        FADD    ST,ST(2)  ;X'            X'  Y'   REAL IMAG 4.0
        TEST    AX,BX     ;CHECK C0
        LOOPNZ  MLOOPB    ;LOOP IF (ITERS > 0) and (RADIUS^2 < 4)

        FNINIT            ;INIT COPROCESSOR TO CLEAR STACK

        MOV     EAX,DWORD PTR K_LIMIT
        SUB     EAX,ECX   ;DONE, LOOP WAS COUNTED DOWNWARD
        MOV     DWORD PTR iters,EAX
    }

    return iters;
}

请注意，迭代循环中没有内存加载/存储操作。

我还问了一个关于StackExchange数学的问题。

Answer 1

在Mandelbrot集合中看到的卷发、海马形状、花蕾以及所有其他令人惊奇的东西都是真实的，不是计算的结果。事实上，计算中的数字越重要——舍入误差越小——计算出的形状就越复杂。个人警告：Mandelbrot集合的编码可能会上瘾！