处理2.1.1-屏幕上一次出现多个项目？

Question

我对编程相对较新，我试图创建一个程序，创建一个紫色的球，我点击它向右移动，直到它离开屏幕，在那里我可以一次在屏幕上有无限个球。我已经做了一个程序来做这个，但我只能有一个在屏幕上一次，如果我点击第二次，第一个球消失，被一个新的球取代。哦，当我点击第二次时，球不是从光标所在的地方开始的，而是从最后一个球在x轴上的地方开始的。救命啊！

代码如下：

int moveX, moveY;

void setup() {
  background(255);
  moveY = 200;
  moveX = 0;
  size(500,400);
}

void mouseClicked() {
moveY = mouseY;
  moveX++;

}

void draw() {
  if (moveX >= 1){
    background(255);
    fill(255, 0, 255);
    ellipse(moveX, moveY, 40, 40);
    moveX++;
    }
}

Answer 1

正如donfuxx所建议的，给每个球自己的坐标。一种方法是使用数组存储多个值（坐标）。

为此，您需要熟悉for循环和数组。它们一开始看起来很可怕，但一旦你掌握了它们的诀窍，它们就很容易了。只要您能想到需要重复的情况，您就可以使用for循环来使您的生活更加轻松。

For循环具有以下语法：

for keyword (3 elements: a start point,an end point(condition) and an increment,(separated by the ; character)

for(int currentPos = 0 ; currentPos < 10; currentPos++){
  println("step: " + currentPos);
}

for(int currentPos = 0 ; currentPos < 10; currentPos+=2){
  println("step: " + currentPos);
}

for(int currentPos = 10 ; currentPos > 0; currentPos--){
  println("step: " + currentPos);
}

这在遍历所有类型的数据（场景中球的坐标等）时非常有用

你如何组织你的数据？您将其放置在列表或数组中。数组包含相同类型的元素并具有设置的长度。声明数组的语法如下所示：

ObjectType[] nameOfArray;

您可以初始化一个空数组：

int[] fiveNumbers = new int[5];//new keyword then the data type and length in sq.brackets

String[] words = {"ini","mini","miny","moe"};

background(255);
String[] words = {"ini","mini","miny","moe"};
for(int i = 0 ; i < words.length; i++){
   fill(map(i,0,words.length, 0,255));
   text(words[i],10,10*(i+1));
}

int ballSize = 40;
int maxBalls = 100;//maximum number of balls on screen
int screenBalls = 0;//number of balls to update
int[] ballsX = new int[maxBalls];//initialize an empty list/array of x coordinates
int[] ballsY = new int[maxBalls];//...and y coordinates
void setup() {
  size(500, 400);
  fill(255, 0, 255);
}
void mouseClicked() {
  if (screenBalls < maxBalls) {//if still have room in our arrays for new ball coordinates
    ballsX[screenBalls] = mouseX;//add the current mouse coordinates(x,y)
    ballsY[screenBalls] = mouseY;//to the coordinate arrays at the current ball index
    screenBalls++;//increment the ball index
  }
}

void draw() {
  println(screenBalls);
  background(255);
  for (int i = 0 ; i < screenBalls; i++) {//start counting from 0 to how many balls are on screen
    ballsX[i]++;//increment the x of each ball
    if(ballsX[i]-ballSize/2 > width) ballsX[i] = -ballSize/2;//if a ball goes off screen on the right, place it back on screen on the left
    ellipse(ballsX[i], ballsY[i], ballSize, ballSize);//display each ball
  }
}