VB.Net异常处理

程序执行期间出现异常是一个例外。例外情况是对程序运行时出现的异常情况的回应，例如尝试除以零。

例外提供了一种将程序的一部分控制权移交给另一部分的方法。VB.Net异常处理基于四个关键字：Try，Catch，Finally和Throw。

• Try：尝试块标识一个代码块，特定的例外将被激活。紧接着是一个或多个Catch块。
• Catch：程序在程序中需要处理问题的地方捕获异常。Catch关键字指示捕获异常。
• Finally: Finally块用于执行一组给定的语句，无论是抛出异常还是不抛出异常。例如，如果打开一个文件，无论是否引发异常，它都必须关闭。
• Throw：当出现问题时，程序抛出异常。这是使用Throw关键字完成的。

语法

假设一个块会引发一个异常，在方法中使用Try和Catch关键字的组合来捕获一个异常。 Try/Catch块放置在可能产生异常的代码周围。Try/Catch块内的代码被称为受保护的代码，Try/Catch的语法如下所示：

Try
    [ tryStatements ]
    [ Exit Try ]
[ Catch [ exception [ As type ] ] [ When expression ]
    [ catchStatements ]
    [ Exit Try ] ]
[ Catch ... ]
[ Finally
    [ finallyStatements ] ]
End Try

可以列出多个catch语句以捕获不同类型的异常，以防try块在不同情况下引发多个异常。

.Net框架中的异常类

在.Net框架中，异常由类表示。.Net Framework 中的异常类主要是直接或间接从System.Exception类派生的。一些从System.Exception类派生的异常类是System.ApplicationException和System.SystemException类。

System.ApplicationException类支持应用程序生成的异常。所以程序员定义的异常应该来自这个类。

System.SystemException类是所有预定义的系统异常的基类。

下表提供了一些从System.SystemException类派生的预定义的异常类：

处理异常

VB.Net以try和catch块的形式为异常处理问题提供了一个结构化的解决方案。使用这些块将核心程序语句与错误处理语句分开。

这些错误处理块是使用Try，Catch和Finally关键字实现的。以下是除零条件发生时抛出异常的一个例子：

Module exceptionProg
   Sub division(ByVal num1 As Integer, ByVal num2 As Integer)
      Dim result As Integer
      Try
          result = num1 \ num2
      Catch e As DivideByZeroException
          Console.WriteLine("Exception caught: {0}", e)
      Finally
          Console.WriteLine("Result: {0}", result)
      End Try
   End Sub
   Sub Main()
      division(25, 0)
      Console.ReadKey()
  End Sub
End Module

当上面的代码被编译并执行时，会产生以下结果：

Exception caught: System.DivideByZeroException: Attempted to divide by zero. 
at ...
Result: 0

创建用户定义的例外

也可以定义你自己的例外。用户定义的异常类是从ApplicationException类派生的。以下示例演示了这一点：

Module exceptionProg
   Public Class TempIsZeroException : Inherits ApplicationException
      Public Sub New(ByVal message As String)
          MyBase.New(message)
      End Sub
   End Class
   Public Class Temperature
      Dim temperature As Integer = 0
      Sub showTemp()
          If (temperature = 0) Then
              Throw (New TempIsZeroException("Zero Temperature found"))
          Else
              Console.WriteLine("Temperature: {0}", temperature)
          End If
      End Sub
   End Class
   Sub Main()
      Dim temp As Temperature = New Temperature()
      Try
          temp.showTemp()
      Catch e As TempIsZeroException
          Console.WriteLine("TempIsZeroException: {0}", e.Message)
      End Try
      Console.ReadKey()
   End Sub
End Module

当上面的代码被编译并执行时，会产生以下结果：

TempIsZeroException: Zero Temperature found

抛出对象

如果它是从System.Exception类直接或间接派生的，则可以抛出一个对象。可以在catch块中使用throw语句来将当前对象引用为：

Throw [ expression ]

以下程序演示了这一点：

Module exceptionProg
   Sub Main()
      Try
          Throw New ApplicationException("A custom exception _
          is being thrown here...")
      Catch e As Exception
          Console.WriteLine(e.Message)
      Finally
          Console.WriteLine("Now inside the Finally Block")
      End Try
      Console.ReadKey()
   End Sub
End Module

当上面的代码被编译并执行时，会产生以下结果：

A custom exception is being thrown here...
Now inside the Finally Block