使用图像可视化处理：像素颜色阈值

Question

图像被操纵，希望用计数器识别每张图片上的每个白点

PImage blk; 
void setup() {
  size(640, 480);   
  blk=loadImage("img.png");
}  

void draw () {
  loadPixels();
  blk.loadPixels();
  int i = 0;
  for (int x = 0; x < width; x++) {
    for (int y = 0; y < height; y++) {
      int loc = x+y*width; 
      pixels [loc] = blk.pixels[loc];
      if (blk.pixels[loc] == 0) {
        if (blk.pixels [loc]+1 != 0) {
          i++;
        }
      }

      float r = red(blk.pixels[loc]);
      float g = green(blk.pixels[loc]);
      float b = blue(blk.pixels[loc]); 

      pixels [loc] = color(r, g, b);
    }
  }
  System.out.println (i);
  updatePixels();
}

主要问题在我的if语句中，不确定是否合乎逻辑。

Answer 1

我不确定这到底是怎么回事，但我可以帮你找到白色像素。在这里，我刚刚数了7457个“白色”像素（然后我把它们变成红色，这样你就可以看到它们在哪里，如果你想得到更多或更少的像素，可以调整阈值）：

当然，这只是一个概念证明，你应该能够适应你的需求。

PImage blk; 
void setup() {
  size(640, 480);   
  blk=loadImage("img.png");
  blk.loadPixels();

  int whitePixelsCount = 0;

  // I'm doing this in the 'setup()' method because I don't need to do it 60 times per second
  // Once it's done once I can just use the image as modified unless you want several
  // different versions (which you can calculate once anyway then store in different PImages)
  for (int i = 0; i < blk.width * blk.height; i++) {
    float r = red(blk.pixels[i]);
    float g = green(blk.pixels[i]);
    float b = blue(blk.pixels[i]);

    // In RGB, the brightness of each color is represented by it's intensity
    // So here I'm checking the "average intensity" of the color to see how bright it is
    // And I compare it to 100 since 255 is the max and I wanted this simple, but you can 
    // play with this threshold as much as you like
    if ((r+g+b)/3 > 100) {
      whitePixelsCount++;
      // Here I'm making those pixels red so you can see where they are.
      // It's easier to adjust the threshold if you can see what you're doing
      blk.pixels[i] = color(255, 0, 0);
    }
  }

  println(whitePixelsCount);
  updatePixels();
}  

void draw () {
  image(blk, 0, 0);
}

简而言之（你也会在评论中读到这一点），我们根据我们可以调整的阈值计算像素。为了让你更明显，我把“白色”像素涂成红色。你可以根据你看到的这种方式降低或提高阈值，一旦你知道你想要什么，你就可以摆脱颜色。

这里有一个困难，那就是图像不是“黑白的”，而是更灰度的——这是完全正常的，但对于你似乎要做的事情来说，这让事情变得更难。你可能需要做很多修改才能得到你感兴趣的确切比例。如果你在GiMP或其他可以调整对比度和亮度的图像软件中编辑原始图像，可能会有很大帮助。这有点作弊，但它不会马上奏效。这种策略可以帮你省下一些工作。

玩得高兴