理解圆在加工过程中是如何形成的

Question

import ddf.minim.*;

Minim minim;
AudioPlayer player;
PImage img;

void setup() {
  size(728, 546);

  minim = new Minim(this);

  player = minim.loadFile("Bassnectar_-_Magical_World_feat.wav");
  player.play();
  img= loadImage("cat-in-shades-.jpg");
}

void draw() {


  image(img, 0, 0);
  tint(0, 100, 150);
  stroke(255);

  strokeWeight(4);
  float a = 0;

  float angle = (2*PI) / 200;


  for(int i=0; i < player.bufferSize() - 1; i++) {

   //player.mix.get(i) is a value between [-1,1]

    float x = 250 + cos(a) * (20 * player.mix.get(i) + 100);
    float x2 = 540 + cos(a) * (20 * player.mix.get(i) + 100);    

    float y = 230 + sin(a) * (20 * player.mix.get(i) + 100);
    float y2 = 240 + sin(a) * (20 * player.mix.get(i) + 100);


    float xFinal = 250 + cos(a+angle) * (20 * player.mix.get(i+1) + 100);
    float x2Final = 540 + cos(a+angle) * (20 * player.mix.get(i+1) + 100);


    float yFinal = 230 + sin(a+angle) * (20 * player.mix.get(i+1) + 100);    
    float y2Final = 240 + sin(a+angle) * (20 * player.mix.get(i+1) + 100);    


    line(x,y,xFinal,yFinal);
    line(x2,y2,x2Final,y2Final);

    a += angle;

  }

}

void stop() {
  player.close();
  minim.stop();

  super.stop();
}

上面的以下代码用于在Minim库的处理过程中创建音频可视化程序。出于某种原因，我很难看到在代码的For循环中是如何形成一个圆的。总的来说，我还试图分解代码，并对正在发生的事情有更深的理解。我对以下内容感到困惑:'float x=250+cos(a)*(20*player.mix.get(I)+100)；‘20倍加100是用来放大样本的吗？如果是这样，那么为什么圆可视化器不显示时，我摆脱20倍，只有加20000？250是否用于放置背景图像中X轴上的线的起始点？最后，为什么需要“角度”这个变量？当我把它拿出来时，我注意到可视化工具并不像象限之间看起来有一个划分那样流畅。
我一直在玩这段代码，但找不到太多详细解释的示例，因此希望得到任何帮助。谢谢你。

Answer 1

你需要做的第一件事是更好地理解基本三角学。这里有大量的资源：尝试谷歌搜索“Sin cos教程”或“Sin and cos for game Development”或“Sohcahtoa”以获得一系列结果。

但是基本上，如果有一个起点、一个旋转和一个距离，就可以使用sin和cos计算出终点在哪里。计算终点的基本公式是：

endX = startX + cos(rotation)*distance;
endY = startY + sin(rotation)*distance;

您的代码使用这个公式来查找圆周周围的点，这样它就可以在它们之间画线来绘制圆周。圆的每一条线截面是endpoint的2。

void setup(){
  size(500, 500);
}

void draw(){
  background(0);

  //draw white
  stroke(255);

  //the start point- try changing this to mouseX and mouseY
  float centerX = width/2;
  float centerY = height/2;

  //the distance from the start point
  float radius = 100;

  //how far apart the points are
  float angleIncrement = 30;

  //loop to go around the circle. Try changing it to 180 to see what happens.
  for(float angleInDegrees = 0; angleInDegrees <= 360; angleInDegrees+=angleIncrement){

    //the first "end point" is the start point of the line
    float startX = centerX + cos(radians(angleInDegrees))*radius;
    float startY = centerY + sin(radians(angleInDegrees))*radius;

    //the second "end point" is the end point of the line
    //notice that we're adding the angleIncrement to the angle to get the next point
    float endX = centerX + cos(radians(angleInDegrees+angleIncrement))*radius;
    float endY = centerY + sin(radians(angleInDegrees+angleIncrement))*radius;

    //draw the line
    line(startX, startY, endX, endY);

  }
}