向Inno文件部分添加多个源代码行的函数

Question

有没有一个函数或预处理指令可以用来在Inno Setup中的Files部分添加多行？例如，我多次遇到类似如下的模式:

[Files]
Source: "{#SrcPath}\Dir1\FileName.*"; DestDir: {#DstPath}\Dir1;   
Source: "{#SrcPath}\Dir2\FileName.*"; DestDir: {#DstPath}\Dir2;  
Source: "{#SrcPath}\Dir3\FileName\*"; DestDir: {#DstPath}\Dir3\FileName; Flags: recursesubdirs  

虽然我可以复制和粘贴每一行，但我想知道我是否可以做这样的事情？

[Files]
AddFiles(FileName)

不幸的是，我在文档或在线找不到任何说明如何执行此操作的示例。这可能吗？

Answer 1

使用 #define 指令定义预处理器宏（模板），如下所示：

#define FileTemplate(str FileName) \
  "Source: """ + SrcPath + "\Dir1\" + FileName + ".*""; DestDir: " + DstPath + "\Dir1;" + NewLine + \
  "Source: """ + SrcPath + "\Dir2\" + FileName + ".*""; DestDir: " + DstPath + "\Dir2;" + NewLine + \
  "Source: """ + SrcPath + "\Dir3\" + FileName + ".*""; DestDir: " + DstPath + "\Dir3; Flags: recursesubdirs"

并使用< code>#emit指令展开模板，如下所示:

#define SrcPath "C:\srcpath"
#define DstPath "{app}"

[Files]
#emit FileTemplate("FileName1")
#emit FileTemplate("FileName2")

如果让预处理器转储一个预处理文件，您将看到代码会产生以下结果:

[Files]
Source: "C:\srcpath\Dir1\FileName1.*"; DestDir: {app}\Dir1;
Source: "C:\srcpath\Dir2\FileName1.*"; DestDir: {app}\Dir2;
Source: "C:\srcpath\Dir3\FileName1.*"; DestDir: {app}\Dir3; Flags: recursesubdirs
Source: "C:\srcpath\Dir1\FileName2.*"; DestDir: {app}\Dir1;
Source: "C:\srcpath\Dir2\FileName2.*"; DestDir: {app}\Dir2;
Source: "C:\srcpath\Dir3\FileName2.*"; DestDir: {app}\Dir3; Flags: recursesubdirs

对于NewLine预定义的预处理器变量，您需要Inno Setup 6。另请参阅在Inno Setup预处理器中发出新行。