Inno 设置 [代码] 部分变量为 [注册表]

Question

我在进行 Inno 设置时遇到问题。

我在这里的[code]部分使用分辨率检测脚本：
INNO设置：如何获取主监视器的分辨率？

现在，我想将< code>xres和< code>yres值放入安装程序的< code>[Registry]部分，如下所示。

Root: HKCU; Subkey: "Software\MyApp\Settings"; Flags: uninsdeletekey; ValueType: dword; \
    ValueName: "ScreenWidth"; ValueData: "XRES"
Root: HKCU; Subkey: "Software\MyApp\Settings"; Flags: uninsdeletekey; ValueType: dword; \
    ValueName: "ScreenHeight"; ValueData: "YRES"

我尝试了这种方法如何在 Inno Setup 中使用 Pascal 变量？，但我无法让它工作。我多次尝试自己解决问题，但我放弃了......

有人能帮我解释一下怎么做吗？< br >我是Inno设置的新手，尤其是Pascal。

Answer 1

一种方法是为两个维度编写一个脚本常量函数，并通过传递的参数返回水平或垂直解析度。其余的在Inno安装引擎上：

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program

[Registry]
; the GetResolution function used in the following {code:...} scripted constants
; takes as parameter X to retrieve horizontal resolution, Y to retrieve vertical
Root: HKCU; Subkey: "Software\MyApp\Settings"; Flags: uninsdeletekey; ValueType: dword; \
   ValueName: "ScreenWidth"; ValueData: "{code:GetResolution|X}"
Root: HKCU; Subkey: "Software\MyApp\Settings"; Flags: uninsdeletekey; ValueType: dword; \
    ValueName: "ScreenHeight"; ValueData: "{code:GetResolution|Y}"

[Code]
function GetSystemMetrics(nIndex: Integer): Integer;
  external '[e-mail] stdcall';

const
  SM_CXSCREEN = 0;
  SM_CYSCREEN = 1;

function GetResolution(Param: string): string;
begin
  // in the {code:...} constant function call we are passing either
  // X or Y char to its parameter (here it is the Param parameter),
  // so let's decide which dimension we return by the Param's first
  // char (uppercased to allow passing even small x and y)
  case UpperCase(Param[1]) of
    'X': Result := IntToStr(GetSystemMetrics(SM_CXSCREEN));
    'Y': Result := IntToStr(GetSystemMetrics(SM_CYSCREEN));
  end;
end;