使用Neo4j合并具有相同数据的节点

Question

这是我想做的：将用户连接到他们观看的视频，就像用户-

我是如何做到的：

LOAD CSV WITH HEADERS FROM 'asdfjkl;' AS line
CREATE (u {user: line.user }) - [:VIEW] -> (v {video: line.video})
RETURN u, v

CSV文件有2列，标题为用户和视频。用户下面是一个标识每个用户的数字，视频下面是一个标识每个视频的数字。一个用户对一个视频。有时用户的名字会在列表中再次出现在不同的视频中。有时视频编号会再次出现，因为它是由不同的用户观看的。

但是，这将返回关系用户在每个关系中查看1个视频。因此，每个用户和视频都有多个节点。

我想做的：创建更多的网络或图形数据库，以查看所有用户正在查看哪些视频以及哪些用户正在观看哪些视频。为此，用户和视频不能像现在这样以一对一的关系连接。

我怎么能这样做？提前谢谢你！

Answer 1

“合并”（MERGE）将确保在缺少节点/关系时创建节点/关系，或者使用它们。自第行起。用户和线路。视频似乎相当于主键，这应该可以很好地工作

LOAD CSV WITH HEADERS FROM 'asdfjkl;' AS line
MERGE (u {user: line.user })
MERGE (v {video: line.video})
MERGE (u)-[:VIEW]->(v) 
RETURN u, v

有关合并的详细信息：http://neo4j.com/docs/2.2.2/query-merge.html

Answer 2

添加到Luanes答案。

您需要使用标签并提供约束！

LOAD CSV WITH HEADERS FROM 'asdfjkl;' AS line
MERGE (u:User {user: line.user })
MERGE (v:Video {video: line.video})
MERGE (u)-[:VIEW]->(v) 
RETURN u, v

您需要在：User（User）和：Video（Video）`上创建一个约束，以使其正常工作。

如果导入的数据量较大(

而是将其拆分为三个查询：

CREATE CONSTRAINT ON (u:User) ASSERT u.user IS UNIQUE;
CREATE CONSTRAINT ON (v:Video) ASSERT v.video IS UNIQUE;

USING PERIODIC COMMIT 100000
LOAD CSV WITH HEADERS FROM 'asdfjkl;' AS line
WITH distinct line.user as user_data
MERGE (:User {user: user_data });

USING PERIODIC COMMIT 100000
LOAD CSV WITH HEADERS FROM 'asdfjkl;' AS line
WITH distinct line.video as video_data
MERGE (:Video {video: video_data });

USING PERIODIC COMMIT 100000
LOAD CSV WITH HEADERS FROM 'asdfjkl;' AS line
MATCH (u:User {user: line.user })
MATCH (v:Video {video: line.video})
MERGE (u)-[:VIEW]->(v);

确保使用最新版本（Neo4j 2.2.2）。