在Drools规则引擎中使用列表

Question

我在试着处理drools中的列表。我正在传递一个请求，其中包含一个购买列表。我想做几个规则，包括检查大小是否正确，然后如果所有元素都相同，如果所有购买都经过授权。。。我有以下代码，但在使用列表时遇到了问题。这是正确的方法吗？尤其是在检查尺寸时？

import com.rules.Purchase
import com.rules.PurchaseRequest

dialect  "mvel"

global Boolean eligibleForRefund

rule "Check for list not equal to two elements" salience 10
    when
        PurchaseRequest(getPurchases != null, getPurchases.size() != 2)

    then
        drools.getKieRuntime().setGlobal("eligibleForRefund", false);
end

rule "Check for two purchases" salience 9
    when:
        $purchaseRequest: PurchaseRequest()
        Number(intValue != 2) from accumulate(Purchase(getStatus() == "Approved") from $purchaseRequest.getPurchases(), count(1))

    then
        drools.getKieRuntime().setGlobal("eligibleForRefund", false);
end

rule "Check for the same purchases" salience 8
    when:
        $purchaseRequest: PurchaseRequest()

    then
        firstPurchase = $purchaseRequest.getPurchases().get(0).getCost();
        hasAllElements = true;

        for (Purchase purchase : $purchaseRequest.getPurchases()) {
            if (purchase.getCost() != firstPurchase) {
                hasAllElements = false;
            }
        }

        drools.getKieRuntime().setGlobal("eligibleForRefund", hasAllElements);
end

Answer 1

假设您的类定义如下所示：

class PurchaseRequest {
  private List<Purchase> purchases;
  
  public List<Purchase> getPurchases() { return this.purchases; }
}

你应该从持有者中取出引用，而不是通过getter不断地与事物交互。在其他项目中，这有助于保持数据的一致性，尤其是与共享资源的一致性。回想一下，如果您有一个名称与格式匹配的getter，您可以简单地将其称为xyz，drools会自动将其映射到getter函数。这允许我们通过PurchaseRequest（$purchases:purchases）获取采购，因为采购将映射到getPurchases（）。（注意，如果purchases碰巧是一个公共变量，那么它应该首先映射到该变量；但由于它是私有的，所以它依赖于遵循bean命名约定的公共getter。）

其次，您在一个非常简单的场景中使用积累，其中收集可能更合适。通常，您会使用积累来处理更复杂的“获取看起来像这样的东西”的情况；但是对于简单的匹配，集合也同样有效。

第三条规则需要做的工作最多。您不希望在规则的右侧执行这种业务逻辑。有很多方法可以检查所有元素是否相同——如果实现了equals/hashCode，可以将所有元素都放入一个集合中，并确认集合的长度仍然是列表的长度；您可以颠倒规则来检查至少一个不同的项目；您可以使用累积或收集。。。

最后--

• 避免突显。它们的设计很糟糕。你的规则应该是独立的。这里只需要突显，因为第三条规则设置了true和false。相反，如果您默认为true，然后使用规则将其覆盖为false，则可以完全不使用显著性

rule "Check for list not equal to two elements" 
salience 1
when
  PurchaseRequest($purchases: purchases != null)
  List(size != 2) from $purchases
then
  drools.getKieRuntime().setGlobal("eligibleForRefund", false);
end

rule "Check for two purchases"
salience 1
when:
  PurchaseRequest( $purchases: purchases != null)
  List( size != 2 ) from collect( Purchase(status == "Approved") from $purchases)
then
  drools.getKieRuntime().setGlobal("eligibleForRefund", false);
end

// I've no idea what data type `getCost()` returns; I'm assuming "String"
rule "Check for the same purchases"
when:
  PurchaseRequest($purchases: purchases != null)

  // accumulate all of the costs into a set. if all costs are the same, set size = 1
  $costs: Set() from accumulate( Purchase( $cost: cost ) from $purchases;
                                 collectSet($cost))
then
  drools.getKieRuntime().setGlobal("eligibleForRefund", $costs.size() == 1);
end