标记前面的空格和规则拆分

Question

感谢这里关于堆栈溢出的答案和一些小时的工作；），我的语法终于如期发挥作用了。只是一些小问题或混乱的情况。

以下是我对lexer的定义：

lexer grammar dnpMDAuslagernLexer;

/*@members {
    public static final int COMMENTS = 1;
}*/

NL
    : [\r\n]
    ;

SUBHEADLINE
    : '##' (~[\r\n])+? '##'
    ;

HEADLINE
    : '#' ('\\#'|~[\r\n])+? '#'
    ;

LEAD
    : '###' (~[\r\n])+? '###'
    ;

SUBHEADING
    : '####' (~[\r\n])+? '####'
    ;

CAPTION
    : '#####' (~[\r\n])+? '#####'
    ;

LISTING
    : '~~~~~' .+? '~~~~~'
    ;

ELEMENTPATH
    : '[[[[[' (~[\r\n])+? ']]]]]'
    ;

LABELREF
    : '{##' (~[\r\n])+? '##}'
    ;

LABEL
    : '{#' (~[\r\n])+? '#}'
    ;

ITALIC
    : '*' (~[\r\n])+? '*'
    ;

SINGLE_COMMENT
    : '//' (~[\r\n])+ -> channel(1)
    ;

MULTI_COMMENT
    : '/*' .*? '*/' -> channel(1)
    ;

STAR
    : '*'
    ;

BRACE_OPEN
    : '{'
    ;

TEXT
    : (~[\r\n*{])+
    ;

下面是解析器的定义：

parser grammar dnpMDAuslagernParser;

options { tokenVocab=dnpMDAuslagernLexer; }

dnpMD
    : head body
    ;

head
    : subheadline headline lead
    ;

subheadline
    : SUBHEADLINE NL+
    ;

headline
    : HEADLINE NL+
    ;

lead
    : LEAD
    ;

subheading
    : SUBHEADING
    ;

caption
    : CAPTION
    ;

listing
    : LISTING (NL listingPath)? (NL label)? NL caption
    ;

image
    : caption (NL label)? (NL imagePath)?
    ;

listingPath
    : ELEMENTPATH
    ;

imagePath
    : ELEMENTPATH
    ;

labelRef
    : LABELREF
    ;

label
    : LABEL
    ;

italic
    : ITALIC
    ;

singleComment
    : SINGLE_COMMENT
    ;

multiComment
    : MULTI_COMMENT
    ;

paragraph
    : TEXT? italic TEXT?
    | TEXT? STAR TEXT?
    | TEXT? labelRef TEXT?
    | TEXT? BRACE_OPEN TEXT?
    | TEXT? LABEL TEXT?
    | ELEMENTPATH
    | TEXT
    ;

newlines
    : NL+
    ;

body
    : bodyElements+
    ;

bodyElements
    : singleComment
    | multiComment
    | paragraph
    | subheading
    | listing
    | image
    | newlines
    ;

看起来lexer文件开头的成员定义在带有ANTLR4插件的IntelliJ IDEA中不起作用？还是我在定义中遗漏了什么。

在标题的定义中，我试图允许开始空白。但是无论我尝试什么，解析过程都失败了。我添加了一个WS标记[\t]，但是当我将WS标记添加到规则中时，它被忽略了。不太确定到底是什么失败了。

但更大的问题是段落规则。有许多子规则，它们试图匹配段落的元素。例如文本或其他一些东西。

我想将此段落用作一个块，以便在解析过程之后，我可以在该段落周围添加一个div-order或其他内容。因为这一段中的所有内容都是一组文本。段落本身用换行符分开。这很有效。

但是在IntelliJ IDEA树视图中，我可以在树中看到不同的段落条目。例如段落： 1，段落： 2等等。那是因为不同的规则。

有没有办法在解析器树中有一个段落条目，并且在它下面都包含文本？只是用换行符拆分？

我尝试了另一条规则作为段落的顶部规则，但这不起作用(

Answer 1

可以使用以下规则避免不同的段落条目：

paragraph
    : (TEXT? italic TEXT?
    | TEXT? STAR TEXT?
    | TEXT? labelRef TEXT?
    | TEXT? BRACE_OPEN TEXT?
    | TEXT? LABEL TEXT?
    | ELEMENTPATH
    | TEXT
    )+
    ;

我想用于不同渠道的成员定义不应该这样做。新的频道定义要好得多：

channels {
    COMMENTS
}

这是独立于语言的，而且效果很好。