尝试使用Java SDK将Amazon Transcribe与ColdFusion结合使用时遇到问题

Question

我正在尝试使用AWS Java SDK开发一个使用Amazon转录服务的ColdFusion应用程序。不幸的是，我对Java的了解很可怜（更不用说SDK本身了），我花了很长时间才实现任何事情。

下面的代码旨在启动转录作业。它不会抛出错误，但也不会启动作业。我甚至不知道它是否正在向AWS发送任何信息。

据我所知，这段代码完全不正确，但目前我最大的两个问题是：

>

我是否错过了一些明显的步骤来实际将请求发送到AWS？

我如何访问AWS返回的任何响应？invokeRequest变量的转储似乎就是请求数据。

提前感谢您的建议。

（FWIW:CF版本为2016，java版本为1.8.0\u 171，AWS SDK为1.11.331）

<cfscript>
   /* Set up credentials */
   awsCredentials = createObject('java','com.amazonaws.auth.BasicAWSCredentials').init('#variables.AWSAccessKeyID#', '#variables.AWSSecretKey#');
   awsStaticCredentialsProvider = CreateObject('java','com.amazonaws.auth.AWSStaticCredentialsProvider').init(awsCredentials);

   /*  Create the Transcribe Service Object*/
   serviceObject = CreateObject('java', 'com.amazonaws.services.transcribe.AmazonTranscribeAsyncClientBuilder').standard().withCredentials(variables.awsStaticCredentialsProvider).withRegion(#variables.awsRegion#).build();


   /* Set up transcription job */
   MediaFileUri = CreateObject('java','com.amazonaws.services.transcribe.model.Media').init();
   MediaFileUri.setMediaFileUri('#variables.mediafilelocation#');
   invokeRequest = CreateObject('java','com.amazonaws.services.transcribe.model.StartTranscriptionJobRequest').init();
   invokeRequest.withLanguageCode('en-US');
   invokeRequest.withMedia(MediaFileUri);
   invokeRequest.withMediaFormat('wav');
   invokeRequest.withTranscriptionJobName('#variables.jobname#');

   /* Check results of request */


   /* Shut down client*/
   serviceObject.shutdown();
</cfscript>

Answer 1

这就是我是如何做到这一点的。我将从头开始，以防任何人读到这篇文章都像我一样感到困惑。

第一步是获取AWS Java SDK。在某种程度上，我的印象是，亚马逊转录服务有一个单独的SDK，但事实并非如此。下载文件后，将以下jar文件放在/{coldfusion}/lib/文件夹中（我不确定所有这些都是必要的，但这对我来说是有用的）：

aws-java-sdk-xxxx.jar
httpclient-xxxx.jar
httpcore-xxxx.jar
jackson-annotations-xxxx.jar
jackson-core-xxxx.jar
jackson-databind-xxxx.jar
jackson-dataformat-cbor-xxxx.jar
joda-time-xxxx.jar

重新启动ColdFusion服务。

转录服务要求要转录的媒体文件在S3中。例如，我使用ColdFusion的本机支持将我的文件放在S3中的一个桶中，我称之为“转录音频”（注意冒号将密钥ID与秘密分开）：

<cffile
 action = "copy"
 source = "c:\temp\myfilename.wav"
 destination = "s3://#variables.AWSAccessKeyID#:#variables.AWSSecretKey#@transcriptaudio/">

然后，媒体的URL将为：

https://s3.{awsregion}.amazonaws.com/transcriptaudio/myfilename.wav

然后这是我开始转录工作的代码：

<cfscript>
    /* Set up credentials */
    awsCredentials = CreateObject('java', 'com.amazonaws.auth.BasicAWSCredentials').init('#variables.AWSAccessKeyID#','#variables.AWSSecretKey#');
    variables.awsStaticCredentialsProvider = CreateObject('java','com.amazonaws.auth.AWSStaticCredentialsProvider').init(awsCredentials);

    /*  Create the Transcribe Service Object*/
    serviceObject = CreateObject('java', 'com.amazonaws.services.transcribe.AmazonTranscribeAsyncClientBuilder').standard().withCredentials(variables.awsStaticCredentialsProvider).withRegion(#variables.awsRegion#).build();

    /* Set up transcription job */
        MediaFileUri = CreateObject('java','com.amazonaws.services.transcribe.model.Media').init();
            MediaFileUri.setMediaFileUri('#variables.mediafileurlstring#');
        requestObject = CreateObject('java','com.amazonaws.services.transcribe.model.StartTranscriptionJobRequest').init();
            requestObject.withLanguageCode('en-US');
            requestObject.withMedia(MediaFileUri);
            requestObject.withMediaFormat('wav');
            requestObject.withTranscriptionJobName('#variables.jobName#');

    /* Send the request */
        sendRequest = serviceObject.startTranscriptionJob(requestObject);

    /* Shut down client*/
    serviceObject.shutdown();
</cfscript>

正如Ageax在评论中指出的那样，转录是异步进行的，所以我有一个单独的CF页面来在它完成后获取成绩单。这段代码基本上假设作业已经完成，但transcritionstatus变量会让我这样做。

<cfscript>
    /* Set up credentials */
    awsCredentials = CreateObject('java','com.amazonaws.auth.BasicAWSCredentials').init('#variables.AWSAccessKeyID#','#variables.AWSSecretKey#');
    variables.awsStaticCredentialsProvider = CreateObject('java','com.amazonaws.auth.AWSStaticCredentialsProvider').init(awsCredentials);

    /*  Create the Transcribe Service Object*/
    serviceObject = CreateObject('java', 'com.amazonaws.services.transcribe.AmazonTranscribeAsyncClientBuilder').standard().withCredentials(variables.awsStaticCredentialsProvider).withRegion(#variables.awsRegion#).build();

    /* Set up results object */
        requestResultObject = CreateObject('java', 'com.amazonaws.services.transcribe.model.GetTranscriptionJobRequest').init();
            requestResultObject.withTranscriptionJobName('#variables.jobName#');

    /*  Get the results */
        requestResult = serviceObject.GetTranscriptionJob(requestResultObject);

    /* parse result object into useful variables */ 
        transcriptionStatus = requestResult.TranscriptionJob.TranscriptionJobStatus.toString();
        transcriptURL = requestResult.TranscriptionJob.Transcript.TranscriptFileUri.toString();
</cfscript>

现在我有了TranscriptURL，当使用cfhttp检索时，它会返回大量不必要的信息，至少供我使用。这是我获取成绩单实际文本的代码（该服务以数组形式返回成绩单，因此，如果出于某种原因，每个工作可能会有多个成绩单，我会在数组上循环）（是的，我在这里切换到CF标记，因为我更喜欢使用标记）：

<CFHTTP url="#variables.transcriptURL#" result="transcriptContentResponse">
<CFSET ResultsStruct = DeserializeJSON(variables.transcriptContentResponse.FileContent)>
<CFSET TranscriptsArray = ResultsStruct.Results.transcripts>

<CFLOOP Array = "#variables.TranscriptsArray#" index="ThisTranscript" >
    <cfoutput>  
         #ThisTranscript['transcript']#
    </cfoutput>
</CFLOOP>