XSL分析字符串->将子字符串匹配到多个变量中

Question

我想知道是否可以使用analysting-string并在RegEx中设置多个组，然后将所有匹配的组存储在变量中以供以后使用。

像这样：

<xsl:analyze-string regex="^Blah\s+(\d+)\s+Bloo\s+(\d+)\s+Blee" select=".">
  <xsl:matching-substring>
    <xsl:variable name="varX">
      <xsl:value-of select="regex-group(1)"/>
    </xsl:variable>                                
    <xsl:variable name="varY">
      <xsl:value-of select="regex-group(2)"/>
    </xsl:variable>        
  </xsl:matching-substring>
</xsl:analyze-string>    

这实际上不起作用，但这正是我想要的，我知道我可以将分析字符串封装在一个变量中，但这似乎很愚蠢，因为对于每个我必须处理正则表达式的组，效率不是很高，我应该能够处理正则表达式一次，并存储所有组以供以后使用。

有什么想法吗？

Answer 1

这种转换表明，为了获得所需的结果，不需要xsl:analyze-string，而是存在一种更简单、通用的解决方案

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="*[matches(., '^Blah\s+(\d+)\s+Bloo\s+(\d+)\s+Blee')]">

    <xsl:variable name="vTokens" select=
      "tokenize(replace(., '^Blah\s+(\d+)\s+Bloo\s+(\d+)\s+Blee', '$1 $2'), ' ')"/>

  <xsl:variable name="varX" select="$vTokens[1]"/>  
  <xsl:variable name="varY" select="$vTokens[2]"/>  

  <xsl:sequence select="$varX, $varY"/>
 </xsl:template>
</xsl:stylesheet>

当应用于此XML文档时：

<t>Blah  123   Bloo  4567  Blee</t>

产生想要的正确结果：

123 4567

在这里，我们不依赖于知道RegEx（可以作为参数提供）和字符串——我们只需将字符串替换为RegEx组的分隔字符串，然后我们对其进行标记，并且Tokenize（）生成的序列中的每个项目都可以很容易地分配给相应的变量。

我们不必在临时文件中找到想要的结果。树——我们只是把它们都放在一个结果序列中。

Answer 2

很好

<xsl:variable name="groups" as="element(group)*">
<xsl:analyze-string regex="^Blah\s+(\d+)\s+Bloo\s+(\d+)\s+Blee" select=".">
<xsl:matching-substring>
  <group>
     <x><xsl:value-of select="regex-group(1)"/></x>
     <y><xsl:value-of select="regex-group(2)"/></y>
  </group>   
</xsl:matching-substring>
</xsl:analyze-string>
</xsl:variable>

帮助？这样您就有了一个名为group的变量，它是带有捕获的group元素的序列。