斯波克-嘲笑外部服务

Question

我在spock框架测试方面是非常新的，我没有找到任何可以找到所需信息的例子。因此，我认为最好的方法是向一个例子展示我需要拥有的东西。

>

例如。斯波克的测试类：

def "getData" (){ // this is test of getData method from ExternalService
  when:
    Result result = externalService.getData()
  then:
    result.msg = 'SUCCESS'
}

public class ExternalService(){
  private ServiceConnector serviceConnector;

  public Result getData(){
    Result result = serviceConnector.callAndGet(); 
    prepareInformation(data);
    updateStatuses(data);
    return result;
  }
}

将数据作为域类：

public class Data {
  private String msg
  private int Id
  // +getters/setters
}

现在我有了getData测试，并且想模拟唯一的方法callandget()。这意味着每次调用CallandGet时，都需要有msg成功的对象数据，但是GetData方法中的所有其他方法都应该正常调用。

很可以理解吗？问题是如何将服务类ExternalService注入/模拟到spock测试类中？

Answer 1

您需要做的是模拟ServiceConnector类并通过构造函数传递它（例如）。见下文：

@Grab('org.spockframework:spock-core:1.0-groovy-2.4')
@Grab('cglib:cglib-nodep:3.1')


import spock.lang.*

class Test extends Specification {
    def 'some spec'() {
        given:    
            def serviceConnector = Mock(ServiceConnector) {
                callAndGet() >> new Result(msg: 'SUCCESS')
            }
            def externalService = new ExternalService(serviceConnector)

        when:
            Result result = externalService.getData()

        then:
            result.msg == 'SUCCESS'
    }
}

public class ExternalService {
  private ServiceConnector serviceConnector

  public ExternalService(ServiceConnector serviceConnector) {
      this.serviceConnector = serviceConnector
  }

  public Result getData() {
    Result result = serviceConnector.callAndGet()

    prepareInformation(result)
    updateStatuses(result)
    result
  }

  private void prepareInformation(Result data) {
  }

  private void updateStatuses(Result data) {
  }
}

public class ServiceConnector {
    public Result callAndGet() {

    }    
}

public class Result {
    String msg
}