Neo4j密码：仅当结束节点存在时才创建关系

Question

基于这个类似的问题，我想要一种性能最好的方法来处理这个场景。

MERGE (n1{id:<uuid>})
SET n1.topicID = <unique_name1>
IF (EXISTS((a:Topic{id:<unique_name1>})) |  CREATE UNIQUE (n1)-[:HAS]->(a))

MERGE (n2{id:<uuid>})
SET n2.topicID = <unique_name2>
IF (EXISTS((a:Topic{id:<unique_name2>})) |  CREATE UNIQUE (n2)-[:HAS]->(a))

不幸的是，IF不存在，并且EXISTS不能用于匹配或查找唯一节点。

null

MERGE (a:TEST{id:1})
WITH a
OPTIONAL MATCH (b:TEST{id:2})
// collect b so that there are no nulls, and rows aren't lost when no match
WITH a, collect(b) AS c
FOREACH(n IN c | CREATE UNIQUE (a)-[:HAS]->(n))
RETURN a

Answer 1

您可以简化一些：

MERGE (a:TEST{id:1})
WITH a
MATCH (b:TEST{id:2})
CREATE UNIQUE (a)-[:HAS]->(b)
RETURN a;

(single)with子句用于将查询拆分为2个子查询。

因此，如果match子查询失败，它只会中止自己的子查询（以及任何后续子查询），而不会回滚以前成功的merge子查询。

MERGE (a:TEST{id:1})
WITH a
MATCH (b:TEST{id:2})
CREATE UNIQUE p=(a)-[:HAS]->(b)
RETURN p;

另外，如果您希望返回A，即使B不存在，您也可以使用APOC函数APOC.do.when：

MERGE (a:TEST{id:1})
WITH a
OPTIONAL MATCH (b:TEST{id:2})
CALL apoc.do.when(
  b IS NOT NULL,
  'MERGE (a)-[:HAS]->(b)',
  '',
  {a: a, b: b}) YIELD value
RETURN a;