Apache FOP：在不知道列表大小的情况下以PDF格式从XML打印列表内容？

Question

我有一个通过Apache FOP转换成PDF的XML，嵌入在Java程序和XSLT中。此XML包含几个项目列表；这些列表在XML中的格式如下:

<NameOfList>
    <Listitem>
        <ListItemAttributeOne/>
        <ListItemAttributeTwo/>
    </ListItem>
    <ListItem>
        <ListItemAttributeOne/>
        <ListItemAttributeTwo/>
    </ListItem>
    <...more ListItems>
</NameOfList>

我不知道有多少列表项，我需要像这样将它们的信息打印在PDF文件中：

（1） 列表项目属性一：＜br＞列表项目属性二：＜br>（2）列表项目属性三：＜br>列表项目属性四：＜br＞（…）＜br>（n）列表项目的属性一：

我通常是一个Java的开发人员，所以我知道如何用Java做到这一点：获取列表项目对象的列表，将它们存储在自定义类型“列表项目”的ArrayList中，并循环遍历ArrayList并打印出它们相关的属性，增加标签（1、2等）。）与每个新项目。

使用XSLT 2.0是否有类似的方法来做到这一点？您可以将XML中的列表读取到数组中，并在动态生成的列表中一次打印一项吗？

Answer 1

这是一个 XSLT 1.0（您甚至不需要 XSLT 2.0 引入的功能），用于转换 XSL-FO 列表中的输入：

XSLT 1.0

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:fo="http://www.w3.org/1999/XSL/Format">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/">
        <fo:root>
            <fo:layout-master-set>
                <fo:simple-page-master master-name="simple" margin="0.5in">
                    <fo:region-body/>
                  </fo:simple-page-master>
            </fo:layout-master-set>
            <fo:page-sequence master-reference="simple">
                <fo:flow flow-name="xsl-region-body">
                    <xsl:apply-templates/>
                </fo:flow>
            </fo:page-sequence>
        </fo:root>
    </xsl:template>

    <xsl:template match="NameOfList">
        <fo:list-block provisional-distance-between-starts="2cm" provisional-label-separation="2mm">
            <xsl:apply-templates select="*"/>
        </fo:list-block>
    </xsl:template>

    <xsl:template match="ListItem">
        <fo:list-item>
            <fo:list-item-label end-indent="label-end()">
                <fo:block>(<xsl:value-of select="position()"/>)</fo:block>
            </fo:list-item-label>
            <fo:list-item-body start-indent="body-start()">
                <xsl:apply-templates/>
            </fo:list-item-body>
        </fo:list-item>
    </xsl:template>

    <xsl:template match="ListItemAttributeOne">
        <fo:block>List Item Attribute One: <xsl:value-of select="."/></fo:block>
    </xsl:template>

    <xsl:template match="ListItemAttributeTwo">
        <fo:block>List Item Attribute Two: <xsl:value-of select="."/></fo:block>
    </xsl:template>
</xsl:stylesheet>

您可能需要根据您的特定需求(页面大小、页边距、字体，...)但是应该能给你一个大概的概念。