spock测试中抛出MissingPropertyException，其中块

Question

我已经使用spock对我的java项目进行了一段时间的单元测试，但遇到了一个问题。我有一个实用程序方法可以从http请求中获取参数，如果http请求为null并且正在尝试使用spock测试它，则可以获取空字符串。我的测试如下所示：

package foo.bar.test

import foo.bah.HttpRequestPropertyLoader
import spock.lang.Unroll
import javax.servlet.http.HttpServletRequest
import spock.lang.Specification

class HttpRequestPropertyLoaderTest extends Specification {

    HttpRequestPropertyLoader subjectUnderTest
    def result

    def setup() {
        subjectUnderTest = new HttpRequestPropertyLoader()
    }

    @Unroll("When my http request is #nullOrNot then when I get parameter from it the response=#response" )
    def "Test load data from request"() {
        given:
        HttpServletRequest mockHttpRequest = Mock()
        mockHttpRequest.getAttribute("foo") >> "bar"
        when:
        result = subjectUnderTest.loadStringFromHttpRequest(httpRequest, "foo")
        then:
        result == response
        where:
        httpRequest     | response | nullOrNot
        null            |  ""      | "null"
        mockHttpRequest | "bar"    | "not null"
    }
}

但是，当我运行这个测试时，我得到以下错误：

groovy。lang.MissingPropertyException:没有这样的属性：mockHttpRequest for class:foo。酒吧测验HttpRequestPropertyLoaderTest位于foo。酒吧测验HttpRequestPropertyLoaderTest。来自请求的测试加载数据（HttpRequestPropertyLoaderTest.groovy）

在做了一些研究之后，我明白了在给定的块之前运行的块，因此出现了错误，但是我只是想知道是否有一个变通方法？

我知道要使用测试之外的变量，我需要用@Shared注释来注释变量，这对我来说似乎是糟糕的做法。每个测试都应该与其他测试完全分开运行，所以真的不希望有一个对象在测试之间保持它的状态。

是否有可能设置Mock对象从where块返回任何其他方式？

Answer 1

按照tim_yates的建议来看https://code.google.com/p/spock/issues/detail?id=15#c4，我发现了一个相当优雅的解决方案，它不需要使用@Shared注释。测试定义现在如下所示：

package foo.bar.test

import foo.bah.HttpRequestPropertyLoader
import spock.lang.Unroll
import javax.servlet.http.HttpServletRequest
import spock.lang.Specification

class HttpRequestPropertyLoaderTest extends Specification {

    HttpRequestPropertyLoader subjectUnderTest
    def result

    def setup() {
        subjectUnderTest = new HttpRequestPropertyLoader()
    }

    @Unroll("When my http request is #nullOrNot then when I get parameter from it the response=#response" )
    def "Test load data from request"() {
        when:
        result = subjectUnderTest.loadStringFromHttpRequest(httpRequest, "foo")
        then:
        result == response
        where:
        httpRequest << {
            HttpServletRequest mockHttpRequest = Mock()
            mockHttpRequest.getAttribute("foo") >> "bar"
            [null, mockHttpRequest]
        }()
        response << ["", "bar"]
        nullOrNot << ["null", "not null"]
    }
}