Spock测试绿色，尽管应用程序代码抛出异常

Question

我使用Groovy和Gradle进行测试。

我的应用程序代码中有以下几行：

Platform.runLater( new Runnable() {
    void run() {
    ....

        FileChooser fc = getFileChooser()
        File file = fc.showOpenDialog( null )

        // if( file != null && file.exists() ) { <--- this is what I have to put
        if( file.exists() ) { 
            println( "file $file exists")
            analyseFile( file )
        }

如果我模拟（使用groovymock，因为javafx.stage.filechooser是final)，以便fc.showopendialog返回null，我希望在file.exists()nullpointerexception.一个是。

但这并没有出现在测试结果中，测试结果都是绿色的。发现这种情况的唯一方法是查看该类的测试结果：然后您会看到显示“stderr”的灰色按钮。

这似乎是因为包络runnable正在“吞噬”它...

Spock中有什么方法可以使runnable中的异常导致测试失败吗？

def "getting a null result from the showOpenDialog should be handled OK"(){
    given:
    FileChooser fc = GroovyMock( FileChooser )
    ConsoleHandler ch = Spy( ConsoleHandler ){ getFileChooser() >> fc }
    ch.setMaxLoopCount 10
    systemInMock.provideLines( "o" )
    fc.showOpenDialog( _ ) >> null

    when:
    com.sun.javafx.application.PlatformImpl.startup( {} )
    ch.loop()
    Thread.sleep( 1000L ) // NB I know this is a rubbish way to handle things... but I'm a newb with Spock!

    then:
    0 * ch.analyseFile( _ )
}

class ConsoleHandler {
    int loopCount = 0
    def maxLoopCount = Integer.MAX_VALUE - 1
    def response
    FileChooser fileChooser = new FileChooser()

    void analyseFile( File file ) {
        // ...
    }
    void loop() {
        while( ! endConditionMet() ){
            print '> '
            response = System.in.newReader().readLine()
            if( response ) response = response.toLowerCase()
            if( response == 'h' || response == 'help' ){
                println "Help: enter h for this help, q to quit"
            }
            else if ( response == 'o' ){
                Platform.runLater( new Runnable() {
                    void run() {
                        FileChooser fc = getFileChooser()
                        File file = fc.showOpenDialog( null )
                        // if( file != null && file.exists() ) {
                        if( file.exists() ) {
                            analyseFile( file )
                        }
                    }
                })
            }
        }
    }
    boolean endConditionMet() {
        loopCount++
        response == 'q' || loopCount > maxLoopCount
    }
    static void main( args ) {
        com.sun.javafx.application.PlatformImpl.startup( {} )
        new ConsoleHandler().loop()
        com.sun.javafx.application.PlatformImpl.exit()
    }
}

另一个可能需要解释的东西是Spock测试代码中的SysteminMock，它允许测试向应用程序代码中的stdin提供文本：

import org.junit.contrib.java.lang.system.TextFromStandardInputStream
import static org.junit.contrib.java.lang.system.TextFromStandardInputStream.emptyStandardInputStream
....
// field of the Test class, of course:
@Rule
public TextFromStandardInputStream systemInMock = emptyStandardInputStream()

my GradleDependencies子句中的对应行是：

testCompile 'com.github.stefanbirkner:system-rules:1.16.0'

...但我认为这可以通过在Groovy测试文件中使用@grab来获得，对吗？

Answer 1

这是我认为唯一可行的前进方向：像这样改变这一点：

else if ( response == 'o' ){
    Platform.runLater(new Runnable() {
        void run() {
            openFileChooser()
        }
    })
}

ConsoleHandler的新方法：

def openFileChooser() {
    FileChooser fc = getFileChooser()
    File file = fc.showOpenDialog( null )
    // if( file != null && file.exists() ) {
    if( file.exists() ) {
        analyseFile( file )
    }
}

新斯波克测试：

def "getting a null result from the showOpenDialog should be handled OK2"(){
    given:
    FileChooser fc = GroovyMock( FileChooser )
    ConsoleHandler ch = Spy( ConsoleHandler ){ getFileChooser() >> fc }
    fc.showOpenDialog( _ ) >> null

    when:
    com.sun.javafx.application.PlatformImpl.startup( {} )
    ch.openFileChooser()
    Thread.sleep( 1000L )

    then:
    0 * ch.analyseFile( _ )
}