Maple中的螺旋矩阵程序

Question

我想写一个过程，采取一个方阵，并有它输出一个螺旋矩阵。

M:=Matrix(3,[[1,2,3],[4,5,6],[7,8,9]]);

S:=Matrix(3,[[1,2,3],[8,9,4],[7,6,5]]);

下面是3x3矩阵

 Spiral := proc(a1,a2,a3,b1,b2,b3,c1,c2,c3)
 local M,S;
 M:=Matrix(3,[[a1,a2,a3],[b1,b2,b3],[c1,c2,c3]]);
 S:=Matrix(3,[[a1,a2,a3],[c2,c3,b1],[c1,b3,b2]]);
 print(M);
 print(S);
 end:

 Spiral(1,2,3,4,5,6,7,8,9);

我很难在Maple中找到关于矩阵的信息。任何关于使用Maple的提示都将不胜感激。谢谢你。

Answer 1

我不认为这个问题有一个特别紧凑的解决办法。这是我想出的一个解决办法。它接受一个方阵作为输入，并返回另一个矩阵，即输入矩阵的螺旋。

spiral:=proc(M::Matrix)
    local size, spiralCount, currentRow, currentCol, MIndex, k;
    local spiralMatrix;

    size := numelems(M[1]);
    spiralCount := size;
    currentRow := 1;
    currentCol := 0;
    MIndex := 0;
    spiralMatrix := Matrix(size, size);

    while spiralCount > 0 do
    for k from 1 to spiralCount do
        currentCol:=currentCol + 1;
        spiralMatrix[currentRow,currentCol] := M[iquo(MIndex,size) + 1,(MIndex mod size) + 1];
        MIndex := MIndex + 1;
    end do:
    for k from 1 to spiralCount-1 do
        currentRow:=currentRow + 1;
        spiralMatrix[currentRow,currentCol] := M[iquo(MIndex,size) + 1,(MIndex mod size) + 1];
        MIndex := MIndex + 1;
    end do:
    for k from 1 to spiralCount-1 do
        currentCol:=currentCol - 1;
        spiralMatrix[currentRow,currentCol] := M[iquo(MIndex,size) + 1,(MIndex mod size) + 1];
        MIndex := MIndex + 1;
    end do:
    for k from 1 to spiralCount-2 do
        currentRow:=currentRow - 1;
        spiralMatrix[currentRow,currentCol] := M[iquo(MIndex,size) + 1,(MIndex mod size) + 1];
        MIndex := MIndex + 1;
    end do:
    spiralCount := spiralCount - 2;
    end do:


    return spiralMatrix;
end proc:


> m:=Matrix([[1,2,3],[4,5,6],[7,8,9]]);
                               [1    2    3]
                               [           ]
                          m := [4    5    6]
                               [           ]
                               [7    8    9]
> spiral(m);       
                             [1    2    3]
                             [           ]
                             [8    9    4]
                             [           ]
                             [7    6    5]

请随时向我询问有关此实现和/或如何使用矩阵类型的任何问题。