Gnuplot更改直方图中条形图的颜色

Question

是否可以动态更改Gnuplot脚本中条的颜色？我有以下脚本

reset
fontsize = 12
set term postscript enhanced eps fontsize
set output "bargraph_speedup.eps"
set style fill solid 1.00 border 0
set style histogram
set style data histogram
set xtics rotate by -45
set grid ytics linestyle 1
set xlabel "Benchmarks" font "bold"
set ylabel "Relative execution time vs. reference implementation" font "bold"
set datafile separator ","
plot 'bm_speedup.dat' using 2:xtic(1) ti "Speedup" linecolor rgb "#00FF00"

这将生成此绘图：

有没有可能使零度以下的色条变成红色？

谢谢，
斯文

Answer 1

直方图似乎不允许你这么做。可能是这样的：

set boxwidth 0.3
f(v)=v<0?1:2
plot 'bm_speedup.dat' using 0:2:(f($2)):xticlabels(1) with boxes ti "Speedup" lc variable

Answer 2

您可以将数据文件分成正值和负值两部分，并分别绘制它们：

plot 'bm_speedup_pos.dat' using 2:xtic(1) ti "Faster" linecolor rgb "#00FF00", \
     'bm_speedup_neg.dat' using 2:xtic(1) ti "Slower" linecolor rgb "#FF0000"

或者，如果你只需要几次生成一些图形，一个常见的技术是在gnuplod中生成原始图形，然后在图像编辑器中进行后处理以调整颜色。如果你走这条路线，我建议让gnu图生成SVG格式的图形，这将给你比任何位图格式都更好看的图形。

Answer 3

您可以使用box样式模拟此行为：

我的测试数据：

zip 2
baz 2
bar -1
cat 4
foo -3

然后用gnuplot绘图：

set style line 1 lt 1 lc rgb "green"
set style line 2 lt 1 lc rgb "red"
set style fill solid
plot 'test.dat'  u (column(0)):2:(0.5):($2>0?1:2):xtic(1) w boxes lc variable
#                  #xval:ydata:boxwidth:color_index:xtic_labels