使用ANTLR4识别单行中的多行注释

Question

我想用ANTLR4解析PostScript代码。我完成了语法，但是一个特定的语言扩展（由其他人引入）会给重新识别带来麻烦。

举个简单的例子：

1: % This is a line comment
2: % The next line just pushes the value 10 onto the stack
3: 10
4: 
5: %?description This is the special line-comment in question
6: /procedure {
7:   /var1 30 def %This just creates a variable
8:   /var2 10 def %?description A description associated with var2 %?default 20
9:   /var3 (a string value) def %?description I am even allowed to use % signs %?default (another value)
10: }

可以使用Lexer规则识别行注释，例如第1、2和7行中的注释

LINE_COMMENT: '%' .*? NEWLINE;
NEWLINE: '\r'? '\n';

只需在%之后匹配所有内容，直到行尾。

我的问题是那些特殊的行注释，它们以类似于<代码>%？说明或%？默认值，因为这些值也应该被识别，但与LINE\u注释不同，可以将多个值放在一行中（例如第8行和第9行）。那么第8行包含两条特殊注释？描述与var2和var2%相关的描述？默认值20。

把它想象成这样的东西（尽管这行不通）：

SPECIAL_COMMENT: '%?' .*? (SPECIAL_COMMENT|NEWLINE);

现在是真正棘手的部分：应该允许您将任意文本放在%之后？描述包括%，同时仍然能够拆分单个注释。

简而言之，问题可以简化为拆分表单的一行

(%?<keyword> <content with % allowed in it>)+ NEWLINE

例如

%?description descr. with % in in %?default (my default value for 100%) %?rest more

进入

1.) %?description descr. with % in in 
2.) %?default (my default value for 100%)
3.) %?rest more

有什么想法吗，如何制定Lexer或Parser规则来实现这一点？

Answer 1

根据这些规则，我认为您必须在lexer中使用谓词来检查输入流中是否出现% 。您还必须确保正常的注释必须以%开头，但后面不能跟着 （或换行符）。

根据语法：

grammar T;

@lexer::members {
  boolean ahead(String text) {
    for (int i = 0; i < text.length(); i++) {
      if (text.charAt(i) != _input.LA(i + 1)) {
        return false;
      }
    }
    return true;
  }
}

parse
 : token* EOF
 ;

token
 : t=SPECIAL_COMMENT {System.out.println("special : " + $t.getText());}
 | t=COMMENT         {System.out.println("normal  : " + $t.getText());}
 ;

SPECIAL_COMMENT
 : '%?' ( {!ahead("%?")}? ~[\r\n] )*
 ;

COMMENT
 : '%' ( ~[?\r\n] ~[\r\n]* )?
 ;

SPACES
 : [ \t\r\n]+ -> skip
 ;

可进行如下测试：

String source = "% normal comment\n" +
    "%?description I am even allowed to use % signs %?default (another value)\n" +
    "% another normal comment (without a line break!)";
TLexer lexer = new TLexer(new ANTLRInputStream(source));
TParser parser = new TParser(new CommonTokenStream(lexer));
parser.parse();

并将打印以下内容：

normal  : % normal comment
special : %?description I am even allowed to use % signs 
special : %?default (another value)
normal  : % another normal comment (without a line break!)

零件<代码>（{！ahead（“%？”）}~[\r\n]*可以如下读取：如果没有“%”在前面，匹配除\r和\n以外的任何字符，并执行此操作零次或多次。