使用捕获的类型键入类的属性

Question

我遵循了关于在Perl 6中如何使类变为参数化的SO问题的答案中的说明？。然而，我遇到了一些软路障；我试图使用类型捕获键入内部类的属性，并出现以下错误：

Died with X::TypeCheck::Assignment
  in submethod BUILDALL at ...
  in method insert at ...
  in block <unit> at ...

在下面的示例中，我键入了类BinaryNode's$。项属性（带有T），但这样做会导致上述错误：

class BinarySearchTree {
    my role BTSImpl[::T] {
        my class BinaryNode is rw {
            has T $.item; 
            has BinaryNode $.left;
            has BinaryNode $.right;
        }

        method create-node( T $x ) {
            BinaryNode.new(item => $x)
        }
    }

    method ^parameterize(Mu:U \this, Mu \T) {
        my $type := this.^mixin: BTSImpl[T];
        $type.^set_name: this.^name ~ '[' ~ T.^name ~ ']';
        $type
    }
}

my $bst = BinarySearchTree[Int].new;
$bst.create-node(6);

Answer 1

首先，几乎不需要执行类^参数化角色技巧。它出现在一些内部，因为它有助于处理一些无融资创业问题（根据本身定义语言时的那种乐趣）。然而，在普通的Raku代码中，只需编写一个参数化的角色而不是类。从消费者的角度来看，通常没有区别；人们可以：

• 调用<代码>。在其上新建一个实例（实际上在幕后创建一个类，称为“双关语”，并创建该类的实例）
• 事实上，对类型对象调用任何方法都会得到相同的结果<代码>新的并不特别
• 从它继承（同样，它在自动生成的类上工作）

还有一个额外的好处，就是有人也可以编写它，而不是继承。

其次，在<代码>角色<代码>内部定义的<代码>类<代码>和封装的<代码>角色<代码>之间没有关系（这是一个一般原则：一个包嵌套在另一个包中并不意味着它们在对象模型级别上有任何关系）。因此，我们需要将其单独泛化并实例化。

这两个因素让我们：

role BinarySearchTree[::T] {
    my role BinaryNode[::T] is rw {
        has T $.item;
        has BinaryNode $.left;
        has BinaryNode $.right;
    }

    method create-node( T $x ) {
        BinaryNode[T].new(item => $x)
    }
}

my $bst = BinarySearchTree[Int].new;
$bst.create-node(6);

这确实应该可以工作，但编译器似乎在二进制节点上的计时错误。我们可以通过强制它将参数化延迟到运行时来解决这个问题；有很多方法可以做到这一点，但编写的二进制节点（BinaryNode）[$（T）]紧凑且便宜（优化后几乎没有额外成本）。从而给出一个有效的解决方案：

role BinarySearchTree[::T] {
    my role BinaryNode[::T] is rw {
        has T $.item;
        has BinaryNode $.left;
        has BinaryNode $.right;
    }

    method create-node( T $x ) {
        BinaryNode[$(T)].new(item => $x)
    }
}

my $bst = BinarySearchTree[Int].new;
$bst.create-node(6);