在Perl 6中传递数据以形成语法规则

Question

不确定语法是否要做这样的事情：我希望在运行时定义标记（将来使用文件中的数据）。所以我编写了一个简单的测试代码，正如预期的那样，它甚至不会编译。

grammar Verb {
  token TOP {
    <root> 
    <ending>
  }
  token root {
    (\w+) <?{ ~$0 (elem) @root }>
  }
  token ending {
    (\w+) <?{ ~$0 (elem) @ending }>
  }
}

my @root = <go jump play>;
my @ending = <ing es s ed>;

my $string = "going";
my $match = Verb.parse($string);
.Str.say for $match<root>;

在Perl 6中执行此类操作的最佳方法是什么？

Answer 1

你采取的方法本可以奏效，但你犯了三个错误。

在编译器使用词法变量声明之前，需要以文本形式显示它们：

my $foo = 42; say $foo; # works
say $bar; my $bar = 42; # compile time error

say .parse: 'going' for

  grammar using-token              {token TOP {         \w+ ing}}, # Nil
  grammar using-regex-with-ratchet {regex TOP {:ratchet \w+ ing}}, # Nil
  grammar using-regex              {regex TOP {         \w+ ing}}; # ｢going｣

regex声明符与token声明符的效果完全相同，只是它默认执行回溯。

您在root令牌中第一次使用\w匹配整个输入'go'，然后无法匹配@root的任何元素。然后，因为没有回溯，整个解析立即失败。

（不要认为这意味着您应该默认使用regex。依赖回溯会大大减慢解析速度，通常不需要它。）

看见https://stackoverflow.com/a/19640657/1077672

这项工作：

my @root = <go jump play>;
my @ending = <ing es s ed>;

grammar Verb {
  token TOP {
    <root> 
    <ending>
  }
  regex root {
    (\w+) <?{ ~$0 (elem) @root }>
  }
  token ending {
    (\w+) <?{ ~$0 (elem) @ending }>
  }
}

my $string = "going";
my $match = Verb.parse($string);

.Str.say for $match<root>;

输出：

go

Answer 2

要匹配数组的任何元素，只需在正则表达式中写入数组变量的名称（以sigil开头）：

my @root = <go jump play>;
say "jumping" ~~ / @root /;        # Matches ｢jump｣
say "jumping" ~~ / @root 'ing' /;  # Matches ｢jumping｣

因此，在您的用例中，唯一棘手的部分是将数组从创建它们的代码（例如通过解析数据文件）传递给需要它们的语法标记。

最简单的方法可能是使其成为动态变量（由twigil表示）：

grammar Verb {
    token TOP {
        <root> 
        <ending>
    }
    token root {
        @*root
    }
    token ending {
        @*ending
    }
}

my @*root = <go jump play>;
my @*ending = <ing es s ed>;

my $string = "going";
my $match = Verb.parse($string);

say $match<root>.Str;

另一种方法是将带有数组的捕获传递给方法副词。解析（parse），这将把它们传递到令牌TOP，然后您可以使用

grammar Verb {
    token TOP (@known-roots, @known-endings) {
        <root: @known-roots>
        <ending: @known-endings>
    }
    token root (@known) {
        @known
    }
    token ending (@known) {
        @known
    }
}

my @root = <go jump play>;
my @ending = <ing es s ed>;

my $string = "going";
my $match = Verb.parse($string, args => \(@root, @ending));

say $match<root>.Str;  # go