Perl6 语法：匹配全行

Question

我刚刚开始探索perl6语法。如何创建一个标记“行”来匹配行首和行尾之间的所有内容？我尝试了以下方法，但没有成功：

my $txt = q:to/EOS/;
    row 1
    row 2
    row 3
    EOS


grammar sample {
    token TOP {
        <line>
    }

    token line {
        ^^.*$$
    }
}

my $match = sample.parse($txt);

say $match<line>[0];

Answer 1

my $txt = q:to/EOS/;
row 1
row 2
row 3
EOS


grammar sample {
    token TOP {
        <line>+
    }
    token line {
        \N+ \n
    }
}

my $match = sample.parse($txt);

say $match<line>[0];

或者如果你能具体说明这一行：

grammar sample {
    token TOP {
        <line>+
    }
    rule line {
        \w+ \d
    }
}

Answer 2

您的原始作品可以通过以下方式进行工作

grammar sample {
    token TOP { <line>+ %% \n }
    token line { ^^ .*? $$ }
}

就我个人而言，我不会尝试锚定行并使用\N。

Answer 3

我可以在这里看到你语法中的两个问题，第一个是标记行，^^和$$是开始和结束行的锚点，但是你可以在它们之间有新行。为了说明这一点，我们先使用一个简单的正则表达式，不使用语法：

my $txt = q:to/EOS/;
    row 1
    row 2
    row 3
    EOS

if $txt ~~ m/^^.*$$/ {
    say "match";
    say $/;
}

运行它，输出是：

match
｢row 1
row 2
row 3｣

您会看到正则html" target="_blank">表达式与所需的匹配更多，但是第一个问题不存在，这是因为棘轮，与令牌匹配将不起作用：

my $txt = q:to/EOS/;
    row 1
    row 2
    row 3
    EOS

my regex r {^^.*$$};
if $txt ~~ &r {
    say "match regex";
    say $/;
} else {
    say "does not match regex";
}
my token t {^^.*$$};
if $txt ~~ &t {
    say "match token";
    say $/;
} else {
    say "does not match token";
}

运行它，输出是：

match regex
｢row 1
row 2
row 3｣
does not match token

我真的不确定为什么，但令牌和锚定$ 似乎不能很好地协同工作。但是，您想要的是搜索除换行符之外的所有内容，换行符是\N*以下语法主要解决您的问题：

grammar sample {
    token TOP {<line>}
    token line {\N+}
}

然而，它只匹配第一次出现的情况，因为您只搜索一行，您可能想要做的是搜索一行可选的垂直空格（在您的情况下，您在字符串末尾有一个新行，但我猜您想选择最后一行，即使末尾没有新行），重复几次：

my $txt = q:to/EOS/;
    row 1
    row 2
    row 3
    EOS

grammar sample {
    token TOP {[<line>\v?]*}
    token line {\N+}
}

my $match = sample.parse($txt);
for $match<line> -> $l {
    say $l;
}

该脚本的输出开始：

｢row 1｣
｢row 2｣
｢row 3｣

此外，为了帮助您使用和调试语法，还有两个非常有用的模块：语法：：跟踪程序和语法：：调试器。只需在脚本的开头包含它们。跟踪器显示由语法完成的匹配的彩色树。调试器允许您实时地看到它一步一步地匹配。