Google sheets-从两个单独的列进行交叉连接/笛卡尔连接

Question

希望有人能帮助我在谷歌表笛卡尔产品。我有两个单独的列中的数据，并希望在一个单独的选项卡中创建这两个列的所有可能组合。第一列是ID（文本），第二列是日期格式。输出应该是两个独立的列。公式应该是动态的，即当新ID或日期添加到输入列表时，列表应该更新。

我在网上寻找解决方案，但还没有找到一个有效的解决方案。我精通Excel，但不太精通Google Sheet:）

这是一张样张：https://docs.google.com/spreadsheets/d/150uIg3XH1hxZa8vSxDhcVZVOcSEOp175OPYL4Rc-wWI/edit?usp=sharing

Answer 1

尝试：

=INDEX(SPLIT(FLATTEN(
 OFFSET('input 1'!A2,,,COUNTA('input 1'!A2:A))&"♠"&TRANSPOSE(
 OFFSET('input 2'!A2,,,COUNTA('input 2'!A2:A)))), "♠"))

并将B列格式设置为日期

Answer 2

我认为soMarios的解决方案在你的情况下更好，但是这里有另一个解决方案只是为了展示一种不同的方法。通过一些工作，这种方法可以推广到任何数量的列。

=ARRAYFORMULA(
  {
    VLOOKUP(
      INT(SEQUENCE(COUNTA('input 1'!A2:A) * COUNTA('input 2'!A2:A), 1,) / COUNTA('input 2'!A2:A)) + 1,
      {SEQUENCE(COUNTA('input 1'!A2:A)), FILTER('input 1'!A2:A, 'input 1'!A2:A <> "")},
      2,
    ),
    VLOOKUP(
      MOD(SEQUENCE(COUNTA('input 1'!A2:A) * COUNTA('input 2'!A2:A), 1,), COUNTA('input 2'!A2:A)) + 1,
      {SEQUENCE(COUNTA('input 2'!A2:A)), FILTER('input 2'!A2:A, 'input 2'!A2:A <> "")},
      2,
    )
  }
)

Answer 3

使用这个：

=ARRAYFORMULA(
  SPLIT(
    FLATTEN(
        FILTER('input 1'!A2:A, 'input 1'!A2:A <> "")
      & ","
      & TRANSPOSE(FILTER('input 2'!A2:A, 'input 2'!A2:A <> ""))
    ),
    ","
  )
)

在单元格A3中，但请确保将B列重新格式化为date（从E列复制格式）：