如何使用Perl 6类表示嵌套数据结构？

Question

上次我不得不处理这样的数据时，我使用了类似于散列数组的东西，其中每个散列都可以有散列值等。在循环遍历不同的索引/键时，很难不丢失，所以我想应该有更好的解决方案。由于我没有OOP经验，我不知道如何开始...

假设在我们的城市里，有一个图书馆（其内容已被数字化为txt文件），有几个房间：1\u red\u room，2\u blue\u room，和3\u white\u room。在每个房间里，都有许多书，每本书都有：作者的名字、标题和文本（从txt文件读取）分为几页（带数字）。

给定一个$字，对于每个房间，程序应列出：

room_name, with the overall number of `$word` contexts in all its books
  list of authors, who use this word, with number of contexts
    for every author, list of books, with number of contexts
      for every book, list of pages, with number of contexts

输出示例：

Word: cucumber
TOTAL: 654
1_red_room: 234
  author: John Smith: 70
    title: "In the wild": 3
      page_50:  1
      page_150: 2
    title: "Hello world": 10
      page_1: 2
      page_5: 1
      page_7: 3
...
...
2_blue_room: 114
  author: Wendy Brown
    title: "In the dark": 43
      page_8: 7
...

那么，有没有一种方法可以借助用户定义的类（或者可能使用其他一些工具）来处理这些数据？




Answer 1

这是我如何开始的。我将创建一个Book类。然后我将为每个房间创建一个书籍%book的哈希值：

my $total-count = 0;
my @room-info;
for @rooms -> $room {
    my @room-authors;
    my %room-authors;
    my $room-count = 0;
    for @(%books{$room}) -> $book {
        my $count = $book.contains-word( $word );
        if $count > 0 {
            $total-count += $count;
            $room-count += $count;
            my $author = $book.author;
            if %room-authors{$author}:exists {
                $(%room-authors{$author}).update($book, $word, $count);
            }
            else {
                %room-authors{$author} = Room-Author.new(
                    book => $book, word => $word, count => $count
                );
                @room-authors.push( $author );
            }
        }
    }
    if @room-authors.elems > 0 {
        @room-info.push(
            Room-Info.new(
                room => $room, room-count => $room-count,
                order => @room-authors, hash => %room-authors
            )
        );
    }
}
say "Word: $word";
say "TOTAL: $total-count";

for @room-info -> $room {
    my @room-authors = $room.order;
    my %room-authors = $room.hash;
    say $room.room ~ " : " ~ $room.room-count;
    for @room-authors -> $author-str {
        my $author = %room-authors{$author-str};
        say "  author: " ~ $author.name ~ " : " ~ $author.count;
        for @($author.titles) -> $title {
            say "    title: " ~ $title.title ~ " : " ~ $title.count;
            for @($title.pages) -> $page {
                say "      page_" ~ $page.page ~ ": " ~ $page.count;
            }
        }
    }
}

在这里，类Page、Title、Room-Info、Book和Room-作者可以看起来像（注意：更多细节必须在真实代码中填写）：

class Page {
    has Int $.page;
    has Int $.count;
}

class Title {
    has Str $.title;
    has Page @.pages;
    has Int $.count;
}

class Room-Info {
    has $.room;
    has $.room-count;
    has @.order;
    has %.hash;
}

class Book {
    has Str $.author;
    has Str $.title;
    has Str $.text;

    # checks how many times a word occurs in the book
    method contains-word ( $word, --> Int ) {
        return 2;  # Stub, insert more code here..
    }

    method get-page-matches( $word ) {
        return [Page.new(page => 50, count => 1),
                Page.new(page => 150, count => 2)]; # Stub, insert more code..
    }
}

class Room-Author {
    has Title @.titles;
    has Bool %!titles;
    has $.name;
    has $.count;

    submethod BUILD(:$book, :$word, :$!count) {
        my $title = $book.title;
        $!name = $book.author;
        %!titles{$title} = True;
        @!titles.push(
            Title.new(title => $title,
                      pages => $book.get-page-matches( $word ),
                      count => $!count,
                     )
        );
    }
    method update( $book, $word, $count ) {
        my $title = $book.title;
        $!count += $count;
        my $author = $book.author; # should be the same as $.name.. 
        if %!titles{$title}:exists {
            die "Unexpected: Duplicate title '$title' for $author";
        }
        else {
            %!titles{$title} = True;
            my Page @pages = $book.get-page-matches( $word );
            @!titles.push(
                Title.new(title => $title,
                          pages => $book.get-page-matches( $word ),
                          count => $count,
                         ) );
        }
    }
}