Terraform导入想要强制存储网关缓存的新资源后申请Terraform

Question

在Terraform支持AWS中的存储网关之前，我通过其他方式创建了三个文件网关。基本上，我使用Terraform来启动支持的BIT（iam策略、s3 bucket、ec2实例、缓存卷），并使用bash脚本进行cli调用来将所有这些整合在一起。效果很好。

现在Terraform支持创建/激活文件网关（包括配置缓存卷），我已经重构了我的Terraform以消除bash脚本。

网关实例和缓存卷是使用以下地形创建的：

resource "aws_instance" "gateway" {
  ami           = "${var.instance_ami}"
  instance_type = "${var.instance_type}"

  # Refer to AWS File Gateway documentation for minimum system requirements.
  ebs_optimized = true
  subnet_id     = "${element(data.aws_subnet_ids.subnets.ids, random_integer.priority.result)}"

  ebs_block_device {
    device_name           = "/dev/xvdf"
    volume_size           = "${var.ebs_cache_volume_size}"
    volume_type           = "gp2"
    delete_on_termination = true
  }

  key_name = "${var.key_name}"

  vpc_security_group_ids = [
    "${aws_security_group.storage_gateway.id}",
  ]
}

实例启动并运行后，bash脚本中的以下片段将查找卷ID并将卷配置为网关缓存：

# gets the gateway_arn and uses that to lookup the volume ID
gateway_arn=$(aws storagegateway list-gateways --query "Gateways[*].{arn:GatewayARN,name:GatewayName}" --output text | grep ${gateway_name} | awk '{print $1}')
volume_id=$(aws storagegateway list-local-disks --gateway-arn ${gateway_arn} --query "Disks[*].{id:DiskId}" --output text)
echo "the volume ID is $volume_id"

# add the gateway cache
echo "adding cache to the gateway"
aws storagegateway add-cache --gateway-arn ${gateway_arn} --disk-id ${volume_id}

这个过程的最终结果是网关在线，配置了缓存卷，但是Terraform状态只知道实例。我随后重构了地形，包括以下内容：

resource "aws_storagegateway_gateway" "nfs_file_gateway" {
  gateway_ip_address = "${aws_instance.gateway.private_ip}"
  gateway_name       = "${var.gateway_name}"
  gateway_timezone   = "${var.gateway_time_zone}"
  gateway_type       = "FILE_S3"
}

resource "aws_storagegateway_cache" "nfs_cache_volume" {
  disk_id     = "${aws_instance.gateway.ebs_block_device.volume_id}"
  gateway_arn = "${aws_storagegateway_gateway.nfs_file_gateway.id}"
}

从那里，我运行以下代码来获取缓存卷的disk_id（注意，我已经编辑了帐户ID和网关ID：

aws storagegateway list-local-disks --gateway-arn arn:aws:storagegateway:us-east-1:[account_id]:gateway/[gateway_id] --region us-east-1

这返回：

{
    "GatewayARN": "arn:aws:storagegateway:us-east-1:[account_id]:gateway/[gateway_id]",
    "Disks": [
        {
            "DiskId": "xen-vbd-51792",
            "DiskPath": "/dev/xvdf",
            "DiskNode": "/dev/sdf",
            "DiskStatus": "present",
            "DiskSizeInBytes": 161061273600,
            "DiskAllocationType": "CACHE STORAGE"
        }
    ]
}

然后，我在aws_storagegateway_cache资源上运行Terraform导入命令，将现有资源拉入状态文件。

我运行的命令：

terraform_11.5 import module.sql_backup_file_gateway.module.storage_gateway.aws_storagegateway_cache.nfs_cache_volume arn:aws:storagegateway:us-east-1:[account_id]:gateway/[gateway_id]:xen-vbd-51792

导入成功完成。然后我运行一个Terraform init和一个Terraform计划，这表明如果我运行一个应用程序，缓存卷将被重新创建。

该计划的产出：

-/+ module.sql_backup_file_gateway.module.storage_gateway.aws_storagegateway_cache.nfs_cache_volume (new resource required)
      id:                     "arn:aws:storagegateway:us-east-1:[account_id]:gateway/[gateway_id]:xen-vbd-51792" => <computed> (forces new resource)
      disk_id:                "xen-vbd-51792" => "1" (forces new resource)
      gateway_arn:            "arn:aws:storagegateway:us-east-1:[account_id]:gateway/[gateway_id]" => "arn:aws:storagegateway:us-east-1:[account_id]:gateway/[gateway_id]"

在导入语句中，我无法为disk_id提供允许完成导入的其他值。我不确定我可以改变什么来避免缓存卷被重新创建，如果运行一个后续的terraform应用。

Answer 1

我已经找到了解决办法@ydaetskcoR—您关于将卷id映射到磁盘id的评论使我找到了所需的地形，以弥合实例声明和缓存声明之间的差距。

这个Terraform块允许我查找ebs_block_device，以便稍后在Terraform中输出正确的disk_id：

data "aws_storagegateway_local_disk" "cache" {
  disk_path   = "/dev/xvdf"
  gateway_arn = "${aws_storagegateway_gateway.nfs_file_gateway.arn}"
}

一旦我添加了这个块，我就重构了配置缓存的Terraform，如下所示：

resource "aws_storagegateway_cache" "nfs_cache_volume" {
  disk_id     = "${data.aws_storagegateway_local_disk.cache.id}"
  gateway_arn = "${aws_storagegateway_gateway.nfs_file_gateway.id}"
}

现在，当我运行terraform init和terraform plan时，网关卷不会显示为需要任何更改或替换。

谢谢你帮我找到这个。

-戴夫