复制范围并粘贴到新工作簿中

Question

这应该真的很简单，但我一直在拖网论坛和答案数小时来寻找答案，但没有运气，所以我（不情愿地）创造了一个我自己的问题。

我要做的只是简单地创建一个新工作簿，并将另一个工作簿的范围粘贴到该工作簿中。听起来很简单..？

我原来的工作簿，让我们叫Book1。我试图创建一个新的工作簿，Book2，我将把单元格A1:B10的值复制到其中。

以下是我代码的一个版本（从第一册打开开始）：

Range("A1:B10").Copy
Set NewBook = Workbooks.Add
    With NewBook
        .SaveAs Filename:="Book2.xls"
    End With
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
    :=False, Transpose:=False

这会给出一个“Range类的pastespecial失败”错误。我已经尝试了以下修复，但没有运气：

• 将“工作簿（”book2.xls“）。激活”添加到代码中
• 删除了PasteSpecial行中的额外参数
• 尝试了'.Paste'而不是'.PasteSpecial'
• 将“Selection.PastEspecial”更改为“ActiveSheet.PastEspecial”
• 显式引用复制范围，包括工作簿和工作表引用
• 首先创建新工作簿，然后执行复制，然后重新激活新工作簿并粘贴

以上解决方案都不起作用...在这个阶段，任何智慧都将被感激地接受！

Answer 1

这就是你要尝试的吗？我已经对代码进行了注释，以便您在理解代码的功能时不会有任何问题。

Option Explicit

Sub Sample()
    Dim wbI As Workbook, wbO As Workbook
    Dim wsI As Worksheet, wsO As Worksheet

    '~~> Source/Input Workbook
    Set wbI = ThisWorkbook
    '~~> Set the relevant sheet from where you want to copy
    Set wsI = wbI.Sheets("Sheet1")

    '~~> Destination/Output Workbook
    Set wbO = Workbooks.Add

    With wbO
        '~~> Set the relevant sheet to where you want to paste
        Set wsO = wbO.Sheets("Sheet1")

        '~~>. Save the file
        .SaveAs Filename:="C:\Book2.xls", FileFormat:=56

        '~~> Copy the range
        wsI.Range("A1:B10").Copy

        '~~> Paste it in say Cell A1. Change as applicable
        wsO.Range("A1").PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, _
        SkipBlanks:=False, Transpose:=False
    End With
End Sub