PL/SQL触发器问题（将数据从表1复制到表2）

Question

我环顾四周，尝试了一些我读过的解决方案。我试图创建一个pl/sql触发器，如果满足子句，它会将数据从一个表复制到另一个表。我觉得我可能只是犯了一个愚蠢的语法错误，而不是一个完全关键的错误，但希望能得到一些帮助。

create or replace TRIGGER TRG_APPLICATIONS
BEFORE INSERT or UPDATE OF APP_ID, Status_id
ON APPLICATIONS
FOR EACH ROW
BEGIN

:new.APP_ID := SEQ_APP_ID.nextval;
:new.APP_DATE := SYSDATE;

IF STATUS_ID = 2 OR STATUS_ID = 5 OR STATUS_ID = 7 OR STATUS_ID = 8 THEN
INSERT INTO APP_HISTORY
SELECT SRN, STATUS_ID, APP_DATE
FROM APPLICATIONS;
END IF;

END;

以下是错误

6.4 PLS-00201：必须声明标识符“STATUS\u ID”

6 1 PL/SQL：语句被忽略

Answer 1

看看这个：

create or replace TRIGGER TRG_APPLICATIONS
  BEFORE INSERT or UPDATE OF APP_ID, Status_id
  ON APPLICATIONS
  FOR EACH ROW
BEGIN

  :new.APP_ID := SEQ_APP_ID.nextval;
  :new.APP_DATE := SYSDATE;

  IF :new.STATUS_ID = 2 OR 
     :new.STATUS_ID = 5 OR 
     :new.STATUS_ID = 7 OR 
     :new.STATUS_ID = 8 THEN

    INSERT INTO APP_HISTORY (srn, status_id, app_date)
     values (:new.srn, :new.status_id, :new.app_date);

 END IF;

END;

Answer 2

可能您需要添加新

IF :NEW.STATUS_ID = 2 OR :NEW.STATUS_ID = 5 
OR :NEW.STATUS_ID = 7 OR :NEW.STATUS_ID = 8 THEN
    INSERT INTO APP_HISTORY (srn, status_id, app_date)
    VALUES (:NEW.SRN, :NEW.STATUS_ID, :NEW.APP_DATE);
END IF;

Answer 3

一旦您注意到需要引用值：NEW以获取此插入或更新的ID状态的当前值，您将遇到第二个错误-您无法查询触发器所在的表，因为其内容在不断变化。您将得到一个变异表错误。更不用说你在SELECT上没有where子句，所以你会将所有应用程序转储到APP_历史记录中。我敢打赌，所有你想要的是复制的行，因为它是在更新之前。当然，插入之前没有行，因此没有任何内容可以复制。还是要在插入时将新值复制到历史记录表中？

假设您希望更新旧值，那么您将：

create or replace TRIGGER TRG_APPLICATIONS
BEFORE INSERT or UPDATE OF APP_ID, Status_id
ON APPLICATIONS
FOR EACH ROW
BEGIN

-- APP_ID better not be the PK or it is changing on UPDATE! 
-- IF you only want this value set once on INSERT, wrap it in an IF INSERTING ... END IF; structure
:new.APP_ID := SEQ_APP_ID.nextval;
:new.APP_DATE := SYSDATE;

IF UPDATING AND ( :NEW.STATUS_ID = 2 OR :NEW.STATUS_ID = 5 OR :NEW.STATUS_ID = 7 OR :NEW.STATUS_ID = 8 )
THEN
   INSERT INTO APP_HISTORY (SRN, STATUS_ID, APP_DATE)
   VALUES (:OLD.SRN, :OLD.STATUS_ID, :OLD.APP_DATE);
END IF;

END;

关于触发器第一次切割的其他想法——触发器在app_id更新时触发，但随后在触发器内再次更改app_id。因此，如果您的用户界面设置了一个APP_ID值，然后使用该值插入相关记录——你只是把它搞砸了。