如何将日期格式转换为UTC格式

Question

在下面的示例中，我们正在尝试将“日期”从一种格式转换为其他格式，例如要转换为UTC格式，例如2021-07-26T18:37:15.490Z

有人能帮忙吗。

输入XML：

<?xml version="1.0" encoding="UTF-8"?>
<date>
<finish_dstamp>20190716140831</finish_dstamp>
</date>

现有输出：

<?xml version="1.0" encoding="UTF-8"?>
<date>
<finish_dstamp>20190716140831</finish_dstamp>
</date>

XSLT代码：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="2.0">

<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

参考URL：https://xsltfiddle.liberty-development.net/pNEj9dB/1

Answer 1

您还可以使用正则表达式解析日期和时间组件。正则表达式和捕获组的示例以构造dateTime值（您也可以将其解析为dateTime以确保有效）

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    version="2.0">
    
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    
    
    <xsl:template match="finish_dstamp/text()">
        <xsl:sequence select="replace(., '(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})', '$1-$2-$3T$4:$5:$6')"/>
    </xsl:template>
</xsl:stylesheet>

使用xsl:analyze-string的示例：

<xsl:template match="finish_dstamp/text()">
    <xsl:analyze-string select="." regex="(\d{{4}})(\d{{2}})(\d{{2}})(\d{{2}})(\d{{2}})(\d{{2}})">
        <xsl:matching-substring>
            <xsl:sequence select="xs:dateTime(
                string-join((
                  string-join((regex-group(1),regex-group(2),regex-group(3)), '-'), 
                  string-join((regex-group(4),regex-group(5),regex-group(6)), ':')), 
                'T')) "></xsl:sequence>
        </xsl:matching-substring>
        <xsl:non-matching-substring>
            <xsl:sequence select="."/>
        </xsl:non-matching-substring>
    </xsl:analyze-string>
</xsl:template>

您可以解析出日期和时间的组件，然后将函数与xs:date（）和xs:time（）参数一起使用，并将其放入与finish\u dstamp/text（）匹配的专用模板中：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    version="2.0">
    
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    
    
    <xsl:template match="finish_dstamp/text()">
        <xsl:sequence select="dateTime(
            xs:date(
              concat(
                substring(., 1, 4), 
                '-',
                substring(., 5, 2),
                '-',
                substring(., 7, 2)
              )
            ),
            xs:time(
              concat(
                substring(., 9, 2),
                ':',
                substring(., 11, 2),
                ':',
                substring(., 13, 2)
              )
            )
          )"/>
    </xsl:template>
</xsl:stylesheet>

您可以解析dateTime的组件并使用xs： dateTime（）构造函数：

<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>


<xsl:template match="finish_dstamp/text()">
    <xsl:sequence select="xs:dateTime(
          concat(
            substring(., 1, 4), 
            '-',
            substring(., 5, 2),
            '-',
            substring(., 7, 2),
            'T',            
            substring(., 9, 2),
            ':',
            substring(., 11, 2),
            ':',
            substring(., 13, 2)
          )
        )"/>
</xsl:template>