Android Gradle -从外部文件加载签名配置

Question

在Gradle for Android中，为发布版本定义签名配置似乎是常见的做法，如下所示：

android {
    signingConfigs {
        debug {
            storeFile file("debug.keystore")
        }

        myConfig {
            storeFile file("other.keystore")
            storePassword "android"
            keyAlias "androiddebugkey"
            keyPassword "android"
        }
    }

    buildTypes {
        foo {
            debuggable true
            jniDebugBuild true
            signingConfig signingConfigs.myConfig
        }
    }
}

问题是，我想把我的build.gradle文件保存在版本控制中，并且在一些git服务器上没有我的密钥库的密码（这与我用于其他东西的密码相同，愚蠢的，我知道）没有好的感觉。

有没有办法从硬盘驱动器上的某个位置从外部文件加载签名配置？

Answer 1

您可以将敏感详细信息移动到单独的签名文件中，并让gradle加载这些信息。

这里有一篇关于如何做的好文章

Answer 2

放入文件签名。属性，其中特定于模块的build.gradle。找到了kts。别忘了将其添加到.gitignore文件中！

signing.properties

storeFilePath=/home/willi/example.keystore
storePassword=secret
keyPassword=secret
keyAlias=myReleaseSigningKey

build.gradle.kts

android {
    // ...
    signingConfigs {
        create("release") {
            val properties = Properties().apply {
                load(File("signing.properties").reader())
            }
            storeFile = File(properties.getProperty("storeFilePath"))
            storePassword = properties.getProperty("storePassword")
            keyPassword = properties.getProperty("keyPassword")
            keyAlias = "release"
        }
    }

    buildTypes {
        getByName("release") {
            signingConfig = signingConfigs.getByName("release")
            // ...
        }
    }
}

Answer 3

我使用类似这样的东西。

我有一个signing.properties在我的应用程序根文件夹。

STORE_FILE=xxxx
STORE_PASSWORD=xxx
KEY_ALIAS=xxx
KEY_PASSWORD=xxx

此文件不在版本控制下打开。当然，您可以更改文件夹。

然后在您的build.gradle中，您可以使用这样的内容：

 android {

        signingConfigs {
            release
        }

        buildTypes {
                release {
                    signingConfig signingConfigs.release
                }     
        }
    }

    def Properties props = new Properties()
    def propFile = file('../signing.properties')
    if (propFile.canRead()){
        props.load(new FileInputStream(propFile))

        if (props!=null && props.containsKey('STORE_FILE') && props.containsKey('STORE_PASSWORD') &&
                props.containsKey('KEY_ALIAS') && props.containsKey('KEY_PASSWORD')) {

            android.signingConfigs.release.storeFile = file(props['STORE_FILE'])
            android.signingConfigs.release.storePassword = props['STORE_PASSWORD']
            android.signingConfigs.release.keyAlias = props['KEY_ALIAS']
            android.signingConfigs.release.keyPassword = props['KEY_PASSWORD']
        } else {
            android.buildTypes.release.signingConfig = null
        }
    }else {
        android.buildTypes.release.signingConfig = null
    }

如果更改文件夹，则必须更改以下行：

 def propFile = file('../signing.properties')