gradle从5.1.1升级到6.4.1后不获取依赖项

Question

这些依赖关系用compile()列在一个依赖项下，这个依赖项是我们的jar库，仍然是用gradle 5.1.1构建的

我们的库存储在一个S3桶中，我们使用shadowjar来生成结束Jar。

例如：

buildscript {

    repositories {
        jcenter()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }

    ext.ver = [
            'springboot': '2.2.0.RELEASE',
            'slf4j'     : '1.7.12'
    ]

    dependencies {
        classpath "org.springframework.boot:spring-boot-gradle-plugin:${ver.springboot}"
        classpath 'io.spring.gradle:dependency-management-plugin:1.0.7.BUILD-SNAPSHOT'
        classpath 'com.github.jengelman.gradle.plugins:shadow:5.2.0'
        classpath 'com.amazonaws:aws-java-sdk-core:1.11.5'
    }
}

apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'maven'
apply plugin: 'com.github.johnrengelman.shadow'
apply plugin: 'maven-publish'
apply plugin: 'org.springframework.boot'
apply plugin: 'io.spring.dependency-management'

compileJava {
    sourceCompatibility = JavaVersion.VERSION_1_8
}

configurations {
    compile.exclude module: 'spring-boot-starter-logging'
    testCompile.exclude module: 'spring-boot-starter-logging'
    runtime.exclude module: 'spring-boot-starter-logging'

    compile.exclude group: 'ch.qos.logback'
}

configurations.all {
    resolutionStrategy.cacheDynamicVersionsFor 10, 'seconds'
    resolutionStrategy.cacheChangingModulesFor 10, 'seconds'
}

dependencyManagement {
    applyMavenExclusions = false
}

repositories {
    mavenLocal()
    maven {
        url "s3://bucket"
        credentials(AwsCredentials) {
            accessKey = awsCredentials.AWSAccessKeyId
            secretKey = awsCredentials.AWSSecretKey
        }
        metadataSources {
            artifact()
        }
    }
    mavenCentral()
}


dependencies {
    compile("com.test:projectB:1.0.0")
     ...
}

import com.github.jengelman.gradle.plugins.shadow.transformers.PropertiesFileTransformer

shadowJar {
    classifier = ''
    baseName = 'project-A'
    manifest {
        attributes 'Main-Class': 'com.test.projectA.Starter'
    }
    mergeServiceFiles()
    append 'META-INF/spring.handlers'
    append 'META-INF/spring.schemas'
    append 'META-INF/spring.tooling'
    transform(PropertiesFileTransformer) {
        paths = ['META-INF/spring.factories']
        mergeStrategy = "append"
    }
}

不幸的是，我不能创建一个真正的复制程序，因为这些库是我工作的公司的真正代码。

谢谢和问候，伊多

Answer 1

S3bucket Maven存储库的metadatasources声明很可能是projectb传递依赖关系没有得到解析的根本原因。这里的文档相当模糊，但我怀疑artifact()只查找实际的jar文件，而不查找POM文件，因此不执行传递依赖解析。当使用开关--info和--refresh-dependencies运行构建时，您应该能够看到这种行为。

谢天谢地，这很容易修复。添加mavenpom()，Gradle将首先尝试解析POM，这样，依赖性解析就会恢复正常。

同时，您可能希望阅读Gradle5 guide中的升级指南，去掉compile配置，转而使用实现。当使用--warning-mode all运行构建时，您应该能够看到类似于此的警告：

The compile configuration has been deprecated for dependency declaration. This will fail with an error in Gradle 7.0. Please use the implementation or api configuration instead. Consult the upgrading guide for further information: https://docs.gradle.org/6.4.1/userguide/upgrading_version_5.html#dependencies_should_no_longer_be_declared_using_the_compile_and_runtime_configurations