如何在Gradle 4.10.3中用Kotlin Gradle DSL从sourceSets中获取' allJava '？

Question

我试图遵循Gradle 4.10.2文档中的Maven发布指南，但是有些困难，因为都是Groovy版本。下面是该示例要求做的事情:

task sourcesJar(type: Jar) {
    from sourceSets.main.allJava
    classifier = 'sources'
}

task javadocJar(type: Jar) {
    from javadoc
    classifier = 'javadoc'
}

这就是我想做的：

tasks.register<Jar>("sourcesJar") {
    from(project(":core").sourceSets.allJava)
    classifier = "sources"
}

tasks.register<Jar>("javadocJar") {
    from(tasks["javadoc"])
    classifier = "javadoc"
}

不幸的是，allJava返回时找不到。在 Kotlin Gradle DSL For Gradle Version 4.10.3 中执行此操作的正确方法是什么？

Answer 1

Kotlin DSL 1.1.3的正确< code>build.gradle.kts语法应该是:

plugins {
    `java-library`
    `maven-publish`
}

tasks.register<Jar>("sourcesJar") {
    from(sourceSets.main.get().allJava)
    archiveClassifier.set("sources")
}

tasks.register<Jar>("javadocJar") {
    from(tasks.javadoc)
    archiveClassifier.set("javadoc")
}

顺便说一下，< code>classifier属性被标记为< code>@Deprecated -您应该改用< code>archiveClassifier。

[更新]

然而，Gradle 4.10.3在DSL 1.0-rc-6中有Kotlin，因此＜code＞构建了.Gradle。kts应类似于：

plugins {
    `java-library`
    `maven-publish`
}

tasks.register<Jar>("sourcesJar") {
    from(sourceSets["main"].allJava)
    classifier = "sources"
}

tasks.register<Jar>("javadocJar") {
    from(tasks["javadoc"])
    classifier = "javadoc"
}