要附加QML滚动条

Question

我有一个问题与列表视图。列表视图太长，它的一部分出现在窗口之外，但我不能附加滚动条。我尝试了许多不同的组合。我认为这个问题在于高度参数，但如果删除它，列表视图只显示第一个条目。

Column{
    anchors.fill: parent
    Row{
        id: buttonsRow
            Button{
                text: "Open dump file"
                onClicked: fileDialog.visible = true
            }
            Button{
                text: "Copy raw data to clipboard"
            }
    }
    ListView{
        id: listView
        anchors.top: buttonsRow.bottom
        height: contentHeight
        //clip: true
        flickableDirection: Flickable.VerticalFlick
        boundsBehavior: Flickable.StopAtBounds
        interactive: true
        model: ListModel{
            id: listModel
        }
        delegate: MDelegate{}
    }
}

有什么方法可以让它滚动吗？

Answer 1

ScrollBar.vertical:ScrollBar{
            id: listView
            anchors.right: parent.right
            visible: listView.contentHeight > listView.height ? true : false
        }

Answer 2

将高度设置为content entHeight可能是问题所在。这将使ListView的高度与其所有项的高度之和一样高。滚动条仅在视图的高度小于其内容的高度时起作用。

这里有一种使用布局的方法：

import QtQuick 2.8
import QtQuick.Controls 2.1
import QtQuick.Layouts 1.3

ApplicationWindow {
    width: 400
    height: 300
    visible: true

    ColumnLayout {
        anchors.fill: parent

        RowLayout {
            id: buttonsRow
            Button {
                text: "Open dump file"
            }
            Button {
                text: "Copy raw data to clipboard"
            }
        }

        ListView {
            id: listView
            flickableDirection: Flickable.VerticalFlick
            boundsBehavior: Flickable.StopAtBounds
            model: 100
            clip: true
            delegate: ItemDelegate {
                text: modelData
            }

            Layout.fillWidth: true
            Layout.fillHeight: true

            ScrollBar.vertical: ScrollBar {}
        }
    }
}

Answer 3

我看不到，在你发布的代码中，你已经附加了一个滚动条。您需要在ListView中包含一个滚动条组件，如下所示：

    ListView { 
        id: listView
        ScrollBar.vertical: ScrollBar {
        active: true
        }
    }

请参阅"附加滚动条到一个闪烁"在https://doc.qt.io/qt-5/qml-qtquick-controls2-scrollbar.html