使用参数将AppleScript编译成应用程序

Question

有一种AppleScript方法：

on displayError(theErrorMessage)
    display dialog theErrorMessage
    return "done"
end displayError

我想编译这个脚本，并将参数传递到（而不是用osascript运行它！）我的申请书。应用程序

类似的东西

osacompile - o My_Application.app My_Script.applescript "This is error message as parameter" 

在这种情况下，我将有编译的应用程序，我可以运行。寻找一个关于如何使用传递参数精确编译脚本的命令。因为编译需要很多时间——我只想做一个。运行后My_Application.app比通过osascript更快。如果输入参数改变了——只需重新编译应用程序。

一个好的选择是以某种方式从运行的应用程序中收集返回值，但这是另一个问题

Answer 1

要获取AppleScript应用程序的命令行参数，可以通过一些AppleScriptObjC使用NSProcessInfo。主要问题是，没有一种简便的方法将结果返回到命令行，因此您需要执行其他操作，例如写入文件。

进程信息参数包括可执行路径，但可以跳过。以这种方式获取参数也适用于osascript，尽管它的路径也被添加到参数中。

以下内容将用作脚本或应用程序：

use framework "Foundation"
use scripting additions

on run
    set arguments to (current application's NSProcessInfo's processInfo's arguments) as list
    if first item of arguments contains "osascript" then set arguments to rest of arguments -- skip osascript path
    if (count arguments) is 1 then set end of arguments to "no arguments"
    repeat with anItem in rest of arguments -- skip the main executable path
        displayError(anItem)
    end repeat
    # osascript still returns the last result
end run

on displayError(theErrorMessage)
    display dialog theErrorMessage
    return "done"
end displayError

在终端上，可以使用多种命令：

/path/to/application.app/Contents/MacOS/applet "this is a test" "Another test"
open /path/to/application.app --args "this is a test" "Another test"
osascript /path/to/script.scpt "this is a test" "another test"

要使用脚本的参数编译AppleScript应用程序，可以在源文件中使用占位符文本，然后使用脚本或文本编辑器替换它。然后可以使用OSAComile shell实用程序将源代码编译成应用程序。它接受一个文本或脚本文件，其结果基于输出文件的扩展名（-o选项）。

举一个完整的例子：

Test.applescript文件（这将被用作模板-占位符文本将在编辑的输出文件中被替换）：

display dialog "This is a test.
It is only a test.

The date is ##DATE##
Some name: ##NAME##
An Identifier: ##ID##

End of test."

应用程序脚本：

use framework "Foundation"
use scripting additions

global arg1 -- this will be the replacement for the NAME parameter
global arg2 -- this will be the replacement for the ID parameter

on run -- example
    try
        set arguments to (current application's NSProcessInfo's processInfo's arguments) as list
        if first item of arguments contains "osascript" then set arguments to rest of arguments
        set arguments to rest of arguments
        if (count arguments) < 2 then set arguments to getArguments()
        set {arg1, arg2} to arguments
        processFile(choose file with prompt "Choose the AppleScript source text file:" of type "com.apple.applescript.text")
    on error errmess
        display alert "Error" message errmess
    end try
end run

to getArguments()
    set theName to text returned of (display dialog "Enter 'Name' parameter:" default answer "Jane Scripter")
    set theID to text returned of (display dialog "Enter 'Identifier' parameter:" default answer "42")
    return {theName, theID}
end getArguments

to processFile(theFile) -- get a list of file items for fixPlaceholders
    set outputFile to (((path to desktop) as text) & "edited.applescript")
    set datePlaceholder to "##DATE##"
    set namePlaceholder to "##NAME##"
    set idPlaceholder to "##ID##"
    set _date to " -e \"s/" & datePlaceholder & "/`date '+%m-%d-%y'`/g\" "
    set _name to " -e \"s/" & namePlaceholder & "/" & arg1 & "/g\" "
    set _id to " -e \"s/" & idPlaceholder & "/" & arg2 & "/g\" "
    set theFile to theFile as text
    set output to (do shell script "cat " & quoted form of ((POSIX path of theFile)) & " | sed " & _date & _name & _id)
    (my output:output toFile:outputFile)
    do shell script "osacompile -o " & quoted form of POSIX path of (((path to desktop) as text) & "Finished.app") & space & quoted form of POSIX path of outputFile
end processFiles

to output:someThing toFile:someFile
    try
        set fileRef to (open for access someFile with write permission)
        set eof of fileRef to 0 -- clear any existing
        write someThing to fileRef -- overwrite
        close access fileRef
    on error errmess
        log errmess
        try -- make sure file is closed on any error
            close access fileRef
        end try
    end try
end output:toFile:

从终端，上述应用程序可以通过使用以下方式运行，其中第一个参数将用于"NAME"参数，第二个参数将用于"ID"参数：

open /path/to/application.app --args "First, Last" "Yep, looks like you."

应用程序将要求源文件（"Test.applescript"，上面），然后输出一个编辑过的源文件和一个由它构建的应用程序到您的桌面上。