如何在 LWJGL 中使用索引和顶点缓冲区实现平面着色？

Question

我目前正在开发一个程序，在Java的LWJGL框架中以3D方式显示建筑物和地形，据我所知，这与OpenGL非常相似。我试图用平面阴影区分建筑物的侧面。例如，我的程序生成的立方体应该如下所示：

为了实现这一点，我尝试在这里实现该方法：https://gamedev.stackexchange.com/questions/152991/how-can-i-calculate-normals-using-a-vertex-and-index-buffer.

这似乎是顶点着色，它以某种梯度对每个像素着色。我的实现目前看起来像这样：

显然这看起来不像我想要的。以下是我的顶点和碎片着色器：

#version 150

in vec3 position;
in vec2 textureCoordinates;
in vec3 normal;

out vec2 pass_textureCoordinates;
out vec3 surfaceNormal;
out vec3 toLightVector;
out vec3 toCameraVector;

uniform mat4 transformationMatrix;
uniform mat4 projectionMatrix;
uniform mat4 viewMatrix;
uniform vec3 lightPosition;

void main(void){

    vec4 worldPosition = transformationMatrix * vec4(position, 1.0);

    gl_Position = projectionMatrix * viewMatrix * worldPosition;
    pass_textureCoordinates = textureCoordinates;

    surfaceNormal = (transformationMatrix * vec4(normal, 0.0)).xyz;
    toLightVector = lightPosition - worldPosition.xyz;
    toCameraVector = (inverse(viewMatrix) * vec4(0.0,0.0,0.0,1.0)).xyz - worldPosition.xyz;

}

#version 150

in vec2 pass_textureCoordinates;
in vec3 surfaceNormal;
in vec3 toLightVector;
in vec3 toCameraVector;

out vec4 out_Color;

uniform sampler2D modelTexture;
uniform vec3 lightColour;
uniform float shineDamper;
uniform float reflectivity;

void main(void){

    vec3 unitNormal = normalize(surfaceNormal);
    vec3 unitLightVector = normalize(toLightVector);

    float nDotl = dot(unitNormal, unitLightVector);
    float brightness = max(nDotl, 0.7);
    vec3 diffuse = brightness * lightColour;

    vec3 unitVectorToCamera = normalize(toCameraVector);
    vec3 lightDirection = -unitLightVector;
    vec3 reflectedLightDirection = reflect(lightDirection, unitNormal);

    float specularFactor = dot(reflectedLightDirection, unitVectorToCamera);
    specularFactor = max(specularFactor, 0.0);
    float dampedFactor = pow(specularFactor, shineDamper);
    vec3 finalSpecular = dampedFactor * reflectivity * lightColour;


    out_Color = vec4(diffuse, 1.0) * texture(modelTexture,pass_textureCoordinates) + vec4(finalSpecular, 1.0);

}

我如何以编程方式为平面着色创建法线数组？

Answer 1

“渐变排序”是由镜面反射高光引起的。如果法向量垂直于立方体的表面，那么朗伯漫射光会给你一个平坦的外观。
您所要做的就是将均匀变量反射率初始化为 0.0。（实际上这是默认值）。

可以通过片段着色器中的偏导数(< code>dFdx，< code>dFdy)或几何着色器中的叉积来计算面法线向量。但是这种选择会导致质量和速度的损失。

_{请参阅
从片段着色器中如何获取表面-不是顶点-法线
3D对象以看起来像2D对象的方式着色}