加工中的连续旋转

Question

我在Procesisng中编写了一个程序，它以随机的颜色和旋转来呈现不透明的立方体，但我希望在程序运行的同时连续地旋转每个立方体。这是我目前的代码,

int boxval = 1;

void setup(){
size (640, 320, P3D);
frameRate(60);
}

void draw(){
  for (int i = 0; i < boxval; i++){
translate(random(0,640), random(0,320), 0); 
rotateY(random(0,360));
rotateX(random(0,360));
rotateZ(random(0,360));
fill(random(0,255),random(0,255),random(0,255),50);
noStroke();
box(64,64,64);
  }
}

Answer 1

这是使用面向对象编程的大好时机！如果我正确理解这个问题，你希望每个立方体独立于其他立方体旋转。让我们做一个立方体类。将每个多维数据集视为一个我们将单独处理的对象。

class Cube {
  float x, y, z; // position of the cube
  float size; // size of cube
  color c; // color of cube
  float xAngle, yAngle, zAngle; // current rotation amount of cube's x, y, z axes
  float xSpeed, ySpeed, zSpeed; // how quickly the cube is rotated in the x, y, z axes 

  // Cube constructor - create the cube and all of its parameters
  Cube(float x_, float y_, float z_, float size_, color c_, float xSpeed_, float ySpeed_, float zSpeed_) {
    x = x_;
    y = y_;
    z = z_;
    size = size_;
    c = c_;
    xSpeed = xSpeed_;
    ySpeed = ySpeed_;
    zSpeed = zSpeed_;

    xAngle = yAngle = zAngle = 0; // starting position
  }

  // update the cube
  // all we're doing is rotating each axis
  void update() {
    xAngle += xSpeed;
    yAngle += ySpeed;
    zAngle += zSpeed;
  }

  // draw the cube to the screen
  void display() {
    pushMatrix(); // need this
    translate(x, y, z); // position on screen
    rotateX(xAngle); // rotation amounts
    rotateY(yAngle);
    rotateZ(zAngle);
    fill(c);
    noStroke(); 
    box(size);
    popMatrix(); // and this
    // push and pop matrix allows for individual cube rotation
    // otherwise you would rotate the whole draw window, which isn't what you're looking for
  }
}

如果希望每个多维数据集在屏幕上改变颜色和位置，但仍然独立旋转，则display()函数可以如下所示：

  void display() {
    pushMatrix(); 
    translate(random(0, width), random(0, height), random(-100, 100)); // random position on screen
    rotateX(xAngle);
    rotateY(yAngle);
    rotateZ(zAngle);
    fill(random(255), random(255), random(255), 50); // random color
    noStroke(); 
    box(size);
    popMatrix();
  }

在处理过程中理解元素的旋转和平移是非常关键的。我强烈推荐这篇来自处理网站的教程，如果你还没有读过的话。我在Cube类中融入了一些概念。

因为您希望在屏幕上绘制多个立方体，所以让我们创建一个立方体数组。我选择了25作为一个任意的数字。

多维数据集[]多维数据集=新多维数据集[25]；

现在，在setup()中，我们需要实际创建每个多维数据集，并为其赋予某些参数，如屏幕上的位置、颜色等。

for (int i = 0; i < cube.length; i++) {
  cube[i] = new Cube(random(0, width), random(0, height), 0, // x, y, z position
  random(30, 80), color(random(255), random(255), random(255), 50), // size, color
  random(0.001, 0.020), random(0.001, 0.020), random(0.001, 0.020)); // xSpeed, ySpeed, zSpeed
}

现在我们只需要将立方体绘制到屏幕上，并更新每个立方体的旋转，这只需要在draw()循环中完成。

for (int i = 0; i < cube.length; i++) {
  cube[i].update();
  cube[i].display()      
}

这是整个程序。每次通过draw()循环调用background()非常重要，这样显示窗口将在每一帧中被清除。注释出来看看会发生什么，但我注意到上面提供的代码段中没有这一点。我想这可能是一种效果！

Cube[] cube = new Cube[25];

void setup() {
  size(640, 320, P3D);
  smooth();
  frameRate(60);

  for (int i = 0; i < cube.length; i++) {
    cube[i] = new Cube(random(0, width), random(0, height), 0, 
    random(30, 80), color(random(255), random(255), random(255), 50), 
    random(0.001, 0.020), random(0.001, 0.020), random(0.001, 0.020));
  }
}

void draw() {
  camera();
  lights();
  background(50);
  for (int i = 0; i < cube.length; i++) {
    cube[i].update();
    cube[i].display();
  }
}

我不确定您的编程背景是什么，但掌握面向对象编程对Processing（和其他OOP语言）确实很有帮助，所以如果您需要速成班，我会推荐Processing网站上的这篇OOP教程。当OOP终于有意义时，我的编程生活发生了改变。