从变量中批量提取路径和文件名

Question

如何从变量中提取路径和文件名？

Setlocal EnableDelayedExpansion
set file=C:\Users\l72rugschiri\Desktop\fs.cfg

我想在不使用任何函数或任何GOTO的情况下做到这一点。可能吗？

Answer 1

所有这些对我都有效：

@Echo Off
Echo Directory = %~dp0
Echo Object Name With Quotations=%0
Echo Object Name Without Quotes=%~0
Echo Bat File Drive = %~d0
Echo Full File Name = %~n0%~x0
Echo File Name Without Extension = %~n0
Echo File Extension = %~x0
Pause>Nul

输出：

Directory = D:\Users\Thejordster135\Desktop\Code\BAT\

Object Name With Quotations="D:\Users\Thejordster135\Desktop\Code\BAT\Path_V2.bat"

Object Name Without Quotes=D:\Users\Thejordster135\Desktop\Code\BAT\Path_V2.bat

Bat File Drive = D:

Full File Name = Path.bat

File Name Without Extension = Path

File Extension = .bat

Answer 2

您只能从（1）BAT本身的参数%1，或（2）调用的参数%1，或（3）变量%a的本地参数中提取路径和文件名。

在帮助电话或帮助中，您可以找到更详细的信息：

%~1-展开%1以删除任何周围的引号（“）
%~f1-将%1扩展为完全限定路径名
%~d1-将%1扩展为仅驱动器号
%~p1-将%1扩展为仅路径
%~n1-将%1扩展为仅文件名
%~x1-将%1扩展为仅文件扩展名
%~s1-扩展路径仅包含短名称
%~a1-将%1扩展为文件属性
%~t1-将%1扩展为文件的日期/时间
%~z1-将%1扩展到文件大小

然后尝试以下方法：

将要解析为参数的字符串传递给调用

call :setfile ..\Desktop\fs.cfg
echo %file% = %filepath% + %filename%
goto :eof

:setfile
set file=%~f1
set filepath=%~dp1
set filename=%~nx1
goto :eof

或者，将文件名作为本地变量传递

for %%a in (..\Desktop\fs.cfg) do (
    set file=%%~fa
    set filepath=%%~dpa
    set filename=%%~nxa
)    
echo %file% = %filepath% + %filename%

Answer 3

@ECHO OFF
SETLOCAL
set file=C:\Users\l72rugschiri\Desktop\fs.cfg
FOR %%i IN ("%file%") DO (
ECHO filedrive=%%~di
ECHO filepath=%%~pi
ECHO filename=%%~ni
ECHO fileextension=%%~xi
)

不太确定你说的没有“功能”是什么意思

很明显，将ECHO更改为SET以设置变量，而不是将其更改为ECHOing...

有关完整列表，请参见文档。

ceztko的测试用例（供参考）

@ECHO OFF
SETLOCAL
set file="C:\Users\ l72rugschiri\Desktop\fs.cfg"
FOR /F "delims=" %%i IN ("%file%") DO (
ECHO filedrive=%%~di
ECHO filepath=%%~pi
ECHO filename=%%~ni
ECHO fileextension=%%~xi
)

评论：请看评论。