将文档中表格中的格式化条目添加到自动更正库

Question

我试图将MSWord 2016文档中的表中的格式化条目添加到自动更正库（如往常一样存储在格式化条目的normal.dotx中）。

在文档中，我有一个包含两列的表，左列为短文本，右列为自动更正条目的格式化长文本。

我有一个工作宏，用于使用行自动更正来存储未格式化的文本。条目。添加名称：=短文本，值：=长文本
我正试图修改它以使用自动更正。条目。AddRichText ShortText，longtext函数，然后该函数应选择表格中的字体和斜体属性。

我尝试了两种方法。

第一个-TestAddressText1

这是代码（去掉了一些化妆品）

Sub testAddRichText1()
    Set oDoc = ActiveDocument
    For i = 1 To oDoc.Tables(2).Rows.Count
        If oDoc.Tables(2).Rows(i).Cells(1).Range.Characters.Count > 1 Then
            ShortText = oDoc.Tables(2).Cell(Row:=i, Column:=1)
            ShortText = Left(ShortText, Len(ShortText) - 2) 'remove the trailing CR and LF
            longtext = oDoc.Tables(2).Cell(Row:=i, Column:=2)
            StatusBar = "Adding " & ShortText & " = " & longtext.Text
            AutoCorrect.Entries.AddRichText ShortText, longtext
        End If
    Next i
    MsgBox "done"
End Sub

使用此代码，从单元格中提取的文本末尾有许多不可打印的字符，大部分是Chr（13）。我尝试在字符串上运行一个清理器来删除所有不可打印的字符，但有些东西不会消失，当使用自动更正时，会在更正文本的末尾出现一个黑框。我想这是表格单元格中的某种密码。尝试打印它的ASC值返回13，但删除它没有效果（只是删除黑盒符号之前的字符）。

第二个测试DDRICHTEXT2

我尝试在我的工作模型中将斜体添加到我的文本字符串中，然后将其与addRichTexthtml" target="_blank">方法一起使用。addRichText需要一个范围，但我无法将文本字符串转换为范围。

这是密码

Sub testAddRichText2()
    Set oDoc = ActiveDocument
    Dim LongTextrng As Range
    For i = 1 To oDoc.Tables(2).Rows.Count
        If oDoc.Tables(2).Rows(i).Cells(1).Range.Characters.Count > 1 Then
            ShortText = oDoc.Tables(2).Cell(Row:=i, Column:=1)
            ShortText = Left(ShortText, Len(ShortText) - 2)
            longtext = oDoc.Tables(2).Cell(Row:=i, Column:=2).Range
            longtext = Left(longtext, Len(longtext) - 2)
            LongTextrng.Text = longtext 'Fails
            LongTextrng.Italic = True
            StatusBar = "Adding " & ShortText & " = " & longtextrng.Text
                AutoCorrect.Entries.Add Name:=ShortText, Value:=LongTextrng
        End If
    Next i
    MsgBox "done"
End Sub

Answer 1

您的第一个示例testAddRichText1几乎是正确的。它失败了，因为尽管您已经意识到需要从短文本中删除尾随字符，但对于长文本却没有这样做。

若要缩短范围，请使用Moveend方法移动范围的末尾。在这种情况下，您需要将区域的末尾向后移动一个字符，以删除单元格标记的末尾。

在第二个示例testAddRichText2中，代码失败，因为您没有正确地将范围分配给变量LongTextrng。将值指定给对象变量时，需要使用Set命令，如下所示：

Set objVar = object

这在您的第一次尝试中并没有失败，因为LongText尚未声明，因此被假定为一个变体。

以下代码适用于您：

Sub AddRichTextAutoCorrectEntries()
    Dim LongText                    As Range
    Dim oRow                        As Row
    Dim ShortText                   As String

    For Each oRow In ActiveDocument.Tables(2).Rows
        If oRow.Cells(1).Range.Characters.Count > 1 Then
            ShortText = oRow.Cells(1).Range.Text
            ShortText = Left(ShortText, Len(ShortText) - 2)
            'assign the range to the variable
            Set LongText = oRow.Cells(2).Range
            'move the end of the range back by 1 character
            LongText.MoveEnd wdCharacter, -1
            StatusBar = "Adding " & ShortText & " = " & LongText.Text
            AutoCorrect.Entries.AddRichText Name:=ShortText, Range:=LongText
        End If
    Next oRow
End Sub