如何更改在VBA中创建的下拉列表的字体大小和格式

Question

我有一个7x16表格的单词模板，默认字体大小为22。此模板用于通过在ms Access中点击按钮生成16周的日历。日历应该是月和日22点，内容7点。这适用于文本，但不是我的下拉列表（应该是7pt字体和斜体）

我尝试使用以下代码将整个单元格的字体大小设置为7pt，但它也将月份和日期设置为7pt：

'Dim DDown As Word.Contentcontrol and curChar As int earlier in code (for context)
Set cel =  tbl.Cell(i, j)
    Set celRange = cel.Range

    celRange.Characters(curChar).Font.Size = 7 'This shrinks everything to 7pt

    celRange.Collapse wdCollapseEnd
    celRange.MoveEnd wdCharacter, -1

    Set DDown = celRange.ContentControls.Add(wdContentControlDropdownList) 

    'Add items to dropdown
    DDown.DropdownListEntries.Add "Shipping within 7 days"
    DDown.DropdownListEntries.Add "On schedule"
    DDown.DropdownListEntries.Add "On Hold"


    Set celRange = cel.Range
    celRange.Collapse wdCollapseEnd
    celRange.MoveEnd wdCharacter, -1
    celRange.Text = vbCrLf  'add a new line between dropdown lists
    celRange.Collapse wdCollapseEnd


    celRange.Select
    Set DDown = Nothing

线路

CelRange。字符（curChar）。字体。大小=7

将单元格中的所有内容缩小到7pt字体，而不仅仅是下拉列表。我还想把下拉列表斜体化。是外观属性吗？

Answer 1

为了应用字体更改，有必要指定应用字体更改的确切范围。理论上，这将是：

ContentControl.Range.Font.Size = 7

但是，下拉内容控件似乎是一种特殊情况。在测试中，如果将字体格式直接应用于内容控件，则只会影响选择列表和占位符文本。但是，当选择条目时，格式将恢复为周围文本的格式。

进一步的实验表明，还需要在文档中创建包含所需格式的字符样式。这需要应用于内容控件和应用的直接格式化。

这是应用格式化的代码

    DDown.DropdownListEntries.Add "Shipping within 7 days"
    DDown.DropdownListEntries.Add "On schedule"
    DDown.DropdownListEntries.Add "On Hold"
    DDown.DefaultTextStyle = "Test7"
    DDown.Range.Font.Size = 7
    DDown.Range.Font.Italic = True

其中"Test7"是我在测试文档中创建的样式名称。

如果无法在文档中预定义样式，则需要动态创建样式。这里有一些示例代码。以下行应位于循环之前（只需执行一次），但应遵循打开/创建Word文档的代码：

    CreateFont7Style ActiveDocument, "DdFont7" 'If the code already has a Document object, use that, not ActiveDocument

（请记住用此处指定的样式名称替换上面代码行中的样式名称，该代码行将样式应用于下拉内容控件！）

CreateFont7Style的代码（您可以命名任何您想要的名称，只需确保在两个位置更改名称）：

Sub CreateFont7Style(doc As Word.Document, styleName As String)
    Dim st As Word.style
    Dim fontSize As Long
    Dim bItalic As Boolean

    fontSize = 7
    bItalic = True

    Set st = doc.styles.Add(styleName, Word.WdStyleType.wdStyleTypeCharacter)
    st.Font.Size = fontSize
    st.Font.Italic = bItalic
End Sub