如何构建不同来源的项目兼容性和目标在gradle中的兼容性

Question

我在gradle文件中的当前配置是

sourceCompatibility = 1.7
targetCompatibility = 1.7

这个规范使我的项目特定于Java1.7。

我的要求是我应该能够为不同的java版本构建我的项目，比如Java1.7和Java1.8

PS：就像gradle中的概要文件构建一样，我们可以指定不同的java版本。

Answer 1

我就是这样解决的

ext.javaVer = project.hasProperty('javaVer') ? project.getProperty('javaVer') : '1.7'
sourceCompatibility = javaVer
targetCompatibility = javaVer

在建设项目中

gradle build -P javaVer=1.8

Answer 2

Gradle使用它在PATH或JAVA_HOME中找到的任何JDK。因此，如果删除sourceCompatibility和targetCompatibility，则应使用项目运行机器上使用的Java版本构建项目。当然，这意味着您不应该在代码中使用类似lambdas的构造，否则Java 7上的编译将失败。

您还应该知道，从Gradle 5开始，对Java 7的支持将被放弃，并且它将只在Java 8（或更新版本）上运行。

另一种方法是在运行时指定JDK，请参见以下链接

如果您想同时为多个Java版本构建，可以使用以下方法：

task compile7(type: JavaCompile) {
   source = fileTree(dir: 'src', include: '**/*.java')
   classpath = sourceSets.main.compileClasspath
   sourceCompatibility = 1.7
   targetCompatibility = 1.7
   destinationDir = file('build/java7')
}
task jar7(type: Jar, dependsOn: compile7) {
   from('build/java7')
   archiveName = 'project-JDK7.jar'
   destinationDir = file('build/jars')
}
task compile8(type: JavaCompile) {
   source = fileTree(dir: 'src', include: '**/*.java')
   classpath = sourceSets.main.compileClasspath
   sourceCompatibility = 1.8
   targetCompatibility = 1.8
   destinationDir = file('build/java8')
}
task jar8(type: Jar, dependsOn: compile8) {
   from('build/java8')
   archiveName = 'project-JDK8.jar'
   destinationDir = file('build/jars')
}

您可以调用gradle jar7 jar8来为您想要的两个java版本构建jars。当然，上面的代码可以改进以参数化操作，像这样：

ext.javaVer = project.hasProperty('javaVer') ? project.getProperty('javaVer') : '1.7'
task compileJ(type: JavaCompile) {
   source = fileTree(dir: 'src', include: '**/*.java')
   classpath = sourceSets.main.compileClasspath
   sourceCompatibility = javaVer
   targetCompatibility = javaVer
   destinationDir = file('build/' + javaVer)
}
task jarJ(type: Jar, dependsOn: compileJ) {
   from('build/' + javaVer)
   archiveName = 'project-' + javaVer + '.jar'
   destinationDir = file('build/jars')
}

使用这种格式，您可以调用gradle jarJ-P javaVer=1.8和gradle jarJ来构建Java8和Java7。