Gradle api传递依赖项不起作用

Question

我有一个库项目，我用它来为我的其他项目保存一些设置，这些项目有很多实用程序分类，也包括实用程序库。因此，我将库的build.gradle中的所有“实现”调用都改为“API”调用，这样我就不需要一次又一次地重新导入依赖项。在构建库并将jar从我的library文件夹移动到主项目中的lib文件夹后，我可以访问库中的所有类，但是传递依赖项在主项目中不可用。

我还尝试使用实现和transivive=true，但没有成功。

我使用的是AdoptopenJDK16和Gradle7.0，并且我已经尝试在清理缓存后重建所有内容。

图书馆建筑

buildscript {
    repositories {
        mavenLocal()
        mavenCentral()
    }
}

plugins {
    id 'java-library'
    id 'idea'
    id 'org.springframework.boot' version '2.5.0'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
}

group = 'com.mygroup'
archivesBaseName = 'utilities'
version = '1.0.2'

bootJar {
    enabled = false
}

jar {
    enabled = true
}

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {

    // Spring
    api('org.springframework.boot:spring-boot-starter-web')
    api('org.springframework.boot:spring-boot-starter-validation')
    api('org.springframework.boot:spring-boot-starter-logging')
    api('org.springframework.boot:spring-boot-starter-log4j2')
    api('org.springframework.boot:spring-boot-starter-test')
    api('io.springfox:springfox-boot-starter:3.0.0')

    // Utilities
    api('io.sentry:sentry-spring:4.3.0')
    api('joda-time:joda-time:2.10.10')
    api('commons-codec:commons-codec:1.15')
    api('org.apache.commons:commons-lang3:3.12.0')
    api('org.apache.commons:commons-csv:1.8')
    api('org.apache.commons:commons-math3:3.6.1')
    api('org.projectlombok:lombok:1.18.20')
    api('org.springframework.boot:spring-boot-configuration-processor')

    // Annotation Processor
    annotationProcessor('org.projectlombok:lombok:1.18.20')
    annotationProcessor('org.springframework.boot:spring-boot-configuration-processor')

    // Tests
    testAnnotationProcessor('org.projectlombok:lombok:1.18.20')
    testAnnotationProcessor('org.springframework.boot:spring-boot-starter-test')
    testImplementation('org.springframework.boot:spring-boot-starter-test')

}

test {
    useJUnitPlatform()
    systemProperties = System.properties as Map<String, ?>
}

应用程序的构建

buildscript {
    repositories {
        mavenLocal()
        mavenCentral()
        maven {
            url 'https://plugins.gradle.org/m2/'
        }
    }
}

plugins {
    id 'java'
    id 'idea'
    id 'org.springframework.boot' version '2.5.0'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
}

group = 'com.mygroup'
archivesBaseName = 'application'
version = '1.0.2'

bootJar {
    enabled = true
}

jar {
    enabled = false
}

repositories {
    mavenLocal()
    mavenCentral()
    flatDir dirs: 'lib'
}

dependencies {

    // Local
    implementation('com.mygroup:utilities:1.0.2')
    testImplementation('com.mygroup:utilities:1.0.2')
    annotationProcessor('com.mygroup:utilities:1.0.2')
    testAnnotationProcessor('com.mygroup:utilities:1.0.2')

    // Additional dependencies
    implementation('org.springframework.boot:spring-boot-starter-data-mongodb')
    implementation('com.graphql-java:graphql-spring-boot-starter:5.0.2')
    implementation('com.graphql-java:graphiql-spring-boot-starter:5.0.2')
    implementation('com.graphql-java:graphql-java-tools:5.2.4')
    
}

test {
    useJUnitPlatform()
    systemProperties = System.properties as Map<String, ?>
}

Answer 1

JAR中没有包含有关传递依赖项的信息。当您通过Maven或Gradle将库发布到存储库时，需要发布几个文件：

• 显然。jar文件包含所有编译代码
• pom.xml文件（包含传递依赖项定义）
• 一些带有校验和的文件

当您只是将库jar复制到lib目录时，您的应用程序没有关于它的依赖项的信息。有几种解决方案：

>

将库发布到Maven存储库（Sonatype Nexus或JFrog Artifactory是最流行的用于设置自承载存储库的产品，但您也可以使用Mavenlocal())而不是将jar复制到lib-我认为这是最好的解决方案

将库构建为fatJar（带有编译代码和所有依赖项的jar文件-在Gradle中创建一个Fat jar）