x86 MASM汇编语言中填充数组后的排序

Question

.data
evenStart    dword          11h
oddStart     dword          20h
darray       dword          15 dup (?)
.code
main PROC
    mov esi, OFFSET darray
    xor ecx, ecx
    
L1: 
    mov ebx, OFFSET evenStart
    test cl,1
    jz iseven
    mov ebx, OFFSET oddStart
    
iseven:
    mov eax, [ebx]
    inc dword ptr [ebx]
    mov dword ptr [esi + 4*ecx],eax
    inc ecx
    cmp ecx,15
    jb L1
    
    exit
main ENDP
END main

所以项目要求我填充未初始化的数组，我做到了。但它也要求我按降序对这个数组进行排序，然后将数组的中间元素放入eax寄存器，并调用dumpregs。这是我陷进去的部分。任何关于如何进行的帮助都是很好的。谢谢！

Answer 1

下一个冒泡排序使用嵌套循环。因为数组有15个元素，所以外部循环在第一次迭代期间可以进行14次比较。对于外部循环的每一次迭代，它必须少做一次比较，因为最小的元素在数组的末尾冒泡了。

    mov ebx, 15-1      ; Outer loop iteration count
OuterLoop:
    mov esi, offset darray

    mov ecx, ebx       ; Inner loop iteration count
InnerLoop:
    lodsd
    mov edx, [esi]
    cmp eax, edx
    jge Skip
    mov [esi-4], edx   ; Swap these 2 elements
    mov [esi], eax
Skip:
    dec ecx
    jnz InnerLoop

    dec ebx
    jnz OuterLoop

未排序数组:11h、20h、12h、21h、13h、22h、14h、23h、15h、24h、16h、25h、17h、26h、18h

排序序列为:26h、25h、24h、23h、22h、21h、20h、18h、17h、16h、15h、14h、13h、12h、11h