通过cython函数与cython方法进行scipy.integrate

Question

我正在尝试研究如何使用cython来加快涉及我定义的类中完成的集成的计算。我试图更好地了解cython如何与用户定义的python类一起工作。我想了解更多有关为什么发生以下描述的错误的信息。

我在名为的文件中有以下cython代码 ex.pyx

from libc.math cimport log
from libc.math cimport sqrt
import scipy.integrate as integ


cdef double integrand_outside(double x):
    """Cython: integrand outside the class"""
    cdef double f = log(x) / sqrt(x)
    return f


cdef class CalcSomething(object):

    def integrate_other(self, double a, double b):
        """This does the integral with the integrand outside the class"""
        return integ.quad(integrand_outside, a, b)[0]

    def integrate_self(self, double a, double b):
        """This does the integral with the integrand inside the class"""
        return integ.quad(self._integrand, a, b)[0]

    def integrate_wrap_self(self, double a, double b):
        """This does the integral with the integrand inside the class"""
        return integ.quad(self.wrap_integrand, a, b)[0]

    def wrap_integrand(self, double x):
        """Python method that wraps _integrand"""
        return self._integrand(x)

    cdef double _integrand(self, double x):
        """Cython: integrand inside the class"""
        cdef double f = log(x) / sqrt(x)
        return f

它显示了scipy.integrate.quad从班级内调用的三种方式

1. 使用在类外部定义的cython被积函数：（integrate_other确定！）
2. 使用在类内部定义的cython被积函数：（integrate_self产生错误）
3. 将在类内部定义的cython被整数函数包装在类内部定义的python函数中：（integrate_wrap_self确定！）

上面的cython代码可以正常编译。现在，我将这些集成方法分别称为

import ex

calcSomething = ex.CalcSomething()

a = 0.001
b = 0.1

calcSomething.integrate_other(a,b)     # works
calcSomething.integrate_wrap_self(a,b) # works
calcSomething.integrate_self(a,b)      # doesn't work

这是回溯：

Traceback (most recent call last):
File "../examples/example.py", line 10, in <module>
print "integrate self =", calcSomething.integrate_self(a,b)   # doesn't work
File "ex.pyx", line 17, in ex.CalcSomething.integrate_self (ex.c:989)
return integ.quad(self._integrand, a, b)[0]
File "/home/alex/Enthought/Canopy_64bit/User/lib/python2.7/site-packages/scipy/integrate/quadpack.py", line 281, in quad
retval = _quad(func,a,b,args,full_output,epsabs,epsrel,limit,points)
File "/home/alex/Enthought/Canopy_64bit/User/lib/python2.7/site-packages/scipy/integrate/quadpack.py", line 345, in _quad
return _quadpack._qagse(func,a,b,args,full_output,epsabs,epsrel,limit)
File "stringsource", line 30, in cfunc.to_py.__Pyx_CFunc_double____CalcSomething____double___to_py.wrap (ex.c:1560)
TypeError: wrap() takes exactly 2 positional arguments (1 given)

这是我的问题：

• 为什么可以scipy.integrate通过cython函数或python方法（因此现在将实例作为第一个参数）传递却不能作为cython方法传递？错误： TypeError: wrap() takes exactly 2 positional arguments (1 given) 暗示问题出在我想通过cython方法传递的实例参数上？

• 这个错误是由于我对cython的误解还是对cython的限制引起的scipy？

• 如果我想通过cython加快速度，我打算在类中计算积分（通过在类中也调用积分函数）的计划不是一个好的解决方案吗？披露：实际代码将调用GSL集成函数，而不是scipy。

Answer 1

从上面的hpaulj的帮助中：答案是该_integrand方法需要声明为cpdefnotcdef

cpdef double _integrand(self, double x):
    """Cython: integrand inside the class"""
    cdef double f = log(x) / sqrt(x)
    return f