数组如何在Java的ByteCode中工作

Question

如果我使用List，Vector之类的普通类size()，则会得到一个返回所考虑类的长度的函数，但是如果我使用一个类的数组或默认数据类型，则会得到一个公共成员的长度，该长度返回当前类的长度。数组的长度。

int a[] = new int[3];
a.length; // used without ()

Vector<Integer> v = new Vector<Integer>();
v.length(); // used with ()

这是为什么？我的意思是数组不是自己的类，不是吗？因此，如果它不是类，则不能有成员变量。我不知道如何在后台处理（字节码）。我知道在内存中的数组存储有指向数组第一个元素的指针，并且内存指针被移至索引（i）ArrayPointer + i*(size of DataType)。

现在您可以说计算机遍历了数组的所有元素并计算了所有元素，但是计算机如何才能知道数组在哪里结束以及下一个数组在哪里开始呢？大小存储在数组中的“成员变量”从何而来？

我的意思是我们经常使用数组，但是我对ByteCode中Java代码背后发生的事情了解得很少。你能告诉我这怎么可能吗？

Answer 1

数组是Java中的对象，但它们并不对应于真实的类。实际上，JVM会在运行中隐式创建数组类，但出于性能原因，它们不是实际的类。

由于它们是对象，因此可以将它们存储在“对象”字段中并像往常一样传递。但是，它们在字节码级别上的处理有所不同。

首先，阵列与所创建的newarray，anewarray或multinewarray为分别单一维度灵长类动物的，单维对象，和多维数组的说明。相反，常规对象是通过new指令创建的。

获取和设置元素是通过*aload和*astore指令完成的。

同样，x.length不是一个实数字段 。而是将其编译为arraylength指令。通过编译以下代码可以看到这一点。

public void test(int size){
    int[] x = new int[size];
    String[] y = new String[size];
    System.out.println(x.length);
    System.out.println(y.length);
}

产生以下字节码

.method public test : (I)V
    .limit stack 2
    .limit locals 4
    iload_1
    newarray int
    astore_2
    iload_1
    anewarray java/lang/String
    astore_3
    getstatic java/lang/System out Ljava/io/PrintStream;
    aload_2
    arraylength
    invokevirtual java/io/PrintStream println (I)V
    getstatic java/lang/System out Ljava/io/PrintStream;
    aload_3
    arraylength
    invokevirtual java/io/PrintStream println (I)V
    return
.end method

尝试length通过手动创建字节码来访问该字段将导致异常，因为该字段实际上不存在。

.method static public main : ([Ljava/lang/String;)V
    .limit stack 1
    .limit locals 1
    aload_0
    getfield [Ljava/lang/String; length I
    return
.end method

结果是

Exception in thread "main" java.lang.VerifyError: Expecting reference to class i
n class ArrayTest at constant pool index 30 in method ArrayTest.main([Ljava/lang
/String;)V
        at java.lang.Class.getDeclaredMethods0(Native Method)
        at java.lang.Class.privateGetDeclaredMethods(Unknown Source)
        at java.lang.Class.getMethod0(Unknown Source)
        at java.lang.Class.getMethod(Unknown Source)
        at sun.launcher.LauncherHelper.getMainMethod(Unknown Source)
        at sun.launcher.LauncherHelper.checkAndLoadMain(Unknown Source)