ANTLR字符串插值

Question

我正在尝试编写一个ANTLR语法，用于解析字符串插值表达式，例如：

my.greeting = "hello ${your.name}"

我得到的错误是：

line 1:31 token recognition error at: 'e'
line 1:34 no viable alternative at input '<EOF>'

MyParser。g4：

parser grammar MyParser;

options { tokenVocab=MyLexer; }

program: variable EQ expression EOF;
expression: (string | variable);
variable: (VAR DOT)? VAR;
string: (STRING_SEGMENT_END expression)* STRING_END;

MyLemus. g4：

lexer grammar MyLexer;

START_STR: '"' -> more, pushMode(STRING_MODE) ;
VAR: (UPPERCASE|LOWERCASE) ANY_CHAR*;
EQ: '=';
DOT: '.';

WHITE_SPACE: (SPACE | NEW_LINE | TAB)+ -> skip;

fragment DIGIT: '0'..'9';
fragment LOWERCASE: 'a'..'z';
fragment UPPERCASE: 'A'..'Z';
fragment ANY_CHAR: LOWERCASE | UPPERCASE | DIGIT;
fragment NEW_LINE: '\n' | '\r' | '\r\n';
fragment SPACE: ' ';
fragment TAB: '\t';

mode INTERPOLATION_MODE;

STRING_SEGMENT_START: '}' -> more, popMode;

mode STRING_MODE;

STRING_END: '"' -> popMode;
STRING_SEGMENT_END: '${' -> pushMode(INTERPOLATION_MODE);
TEXT : ~["$]+ -> more ;

像以下这样的表达式可以正常工作：

my.greeting = "hello"
my.greeting = "hello ${} world"

知道我做错了什么吗？

Answer 1

字符串插值也在官方ANTLR语法库中现有的C#和PHP语法中实现。

Answer 2

好的，我已经计算出（受此启发）我需要在INTERPOLATION_MODE中再次定义默认的lexer规则：

MyLemus. g4：

...
mode INTERPOLATION_MODE;

STRING_SEGMENT_START: '}' -> more, popMode;
I_VAR: (UPPERCASE|LOWERCASE) ANY_CHAR*;
I_DOT: '.';

...

MyParser。g4：

...
variable: ((VAR|I_VAR) (DOT|I_DOT))? (VAR|I_VAR);
...

不过，这似乎有些矫枉过正，所以仍然坚持要找一个有更好答案的人。

Answer 3

而不是：

mode INTERPOLATION_MODE;

STRING_SEGMENT_START: '}' -> more, popMode;
I_VAR: (UPPERCASE|LOWERCASE) ANY_CHAR*;
I_DOT: '.';

...

variable: ((VAR|I_VAR) (DOT|I_DOT))? (VAR|I_VAR);

您可以尝试：

mode INTERPOLATION_MODE;

STRING_SEGMENT_START: '}' -> more, popMode;
I_VAR: (UPPERCASE|LOWERCASE) ANY_CHAR* -> type(VAR);
I_DOT: '.' -> type(DOT);

...

variable: (VAR DOT)? VAR;