Perl 6：使用AT-POS进行可写多维下标访问

Question

您可以使用AT-POS轻松允许下标访问您自己的类：

class Foo
{
    has @.grid;

    method AT-POS($x) is rw { return-rw @!grid[$x] }
    method Str { '<' ~ @!grid.join(' ') ~ '>' }
    method gist { self.Str }
}

my $foo = Foo.new(:grid(<a b c d e>));
say $foo;
say $foo[2];
$foo[3] = 'z';
say $foo;

输出：

<a b c d e>
c
<a b c z e>

但我需要二维下标访问。我已经想出了如何让它在阅读中起作用，但它在写作时就消失了：

class Bar
{
    has @.grid;

    method AT-POS($y, $x) is rw { return-rw @!grid[$y;$x] }
    method Str { '<' ~ @!grid».join(' ').join("\n ") ~ '>' }
    method gist { self.Str }
}

my $bar = Bar.new(:grid(<a b c d e>, <f g h i j>, <k l m n o>));
say $bar;
say $bar[1;2];
$bar[2;3] = 'z';
say $bar;

输出：

<a b c d e
 f g h i j
 k l m n o>
h
Too few positionals passed; expected 3 arguments but got 2
  in method AT-POS at ./p6subscript line 25
  in block <unit> at ./p6subscript line 33

有什么办法可以让这一切顺利吗？

Answer 1

我的解决方案是（前提是我们只有两个维度）：

class Bar {
    has @.grid;

    method TWEAK() { $_ .= Array for @!grid }
    method AT-POS(|c) is raw { @!grid.AT-POS(|c) }
    method Str { '<' ~ @!grid».join(' ').join("\n ") ~ '>' }
    method gist { self.Str }
}

如果给数组的列表尚未转换，则调整将转换这些列表。AT-POS上的是原始就是所需的：返回rw是一种非常迂回的方法。

Answer 2

不知何故，没有调用AT-POS方法。留档提到使用ASSIGN-POS代替，所以我们开始：

class Bar
{
    has @.grid is rw;

    method AT-POS($y, $x) is rw { say "AT-POS $y, $x"; return-rw @!grid[$y;$x] }
    method ASSIGN-POS($y, $x, $new) { say "ASSIGN-POS $y, $x"; @!grid[$y;$x] = $new }
    method Str { '<' ~ @!grid».join(' ').join("\n ") ~ '>' }
    method gist { self.Str }
}

my $bar = Bar.new(:grid(<a b c d e>, <f g h i j>, <k l m n o>));
say $bar;
say $bar[1;2];
$bar[2;3] = 'z';
say $bar;

有趣的是，这产生了另一个错误：

Cannot modify an immutable List ((k l m n o))
  in method ASSIGN-POS at semilist-so.p6 line 8
  in block <unit> at semilist-so.p6 line 16

因此，问题不在于语法，而在于您使用的是不可变列表。您应该使用数组，它是可变的，您将能够做到这一点。

class Bar
{
    has @.grid is rw;

    method AT-POS($y, $x) is rw { return-rw @!grid[$y;$x] }
    method ASSIGN-POS($y, $x, $new) { @!grid[$y;$x] = $new }
    method Str { '<' ~ @!grid».join(' ').join("\n ") ~ '>' }
    method gist { self.Str }
}

my $bar = Bar.new(:grid([<a b c d e>], [<f g h i j>], [<k l m n o>]));
say $bar;
say $bar[1;2];
$bar[2;3] = 'z';
say $bar;