如何通过AT-POS为不同的类实现2d下标？

Question

这里是一个MRE（显示了两次尝试，其中保留了debug以提供帮助），用于尝试在具有系列列的数据帧中使用AT-POS进行2d订阅。。。

class Series does Positional {
    has Real @.data = [0.1,0.2,0.3];

    method AT-POS( $p ) { 
        @!data[$p]
    }   
}

class DataFrame does Positional {
    has Series @.series;

#`[ ATTEMPT #1
    method AT-POS( $p, $q? ) { 
        given $q {
            when Int {                  #say 'Int';
                @!series[$p][$q]
            }   
            when Whatever {             #say '*';
                @!series[$p].data 
            }   
            default {                   #say 'default';
                @!series[$p] 
            }   

        }   
    }   
#]
    # ATTEMPT #2
    method AT-POS(|c) is raw { #`[dd c;] @!series.AT-POS(|c) }
}

my $df = DataFrame.new( series => [Series.new xx 3] );

say $df[1].data;            #[0.1 0.2 0.3]
say $df[1][2];              #0.3
say $df[0,1];               #(Series.new(data => $[0.1, 0.2, 0.3]) Series.new(data => $[0.1, 0.2, 0.3]))
say $df[1;2];               #0.3
say $df[1;*];               #got (0.1) ... expected [0.1 0.2 0.3]
say $df[*;1];               #got (0.2) ... wanted [0.2 0.2 0.2]

我已经研究了SO，在这里、这里和这里发现了三个相关的问题......我代码中的尝试#2试图将@lizmats答案应用于第三个。令人鼓舞的是，我的MRE中的两个尝试都有相同的行为。但是我不能锻炼

• 为什么未输入任何{}选项时（尝试#1）
• |c正在做什么-即使我可以看到它在单下标情况下有效（尝试#2）

我已经用多后缀做了一些实验：

==================

@jonathan在@Lizmat的原始基础上给出了很好的答案-谢谢！这是最终的工作代码：

class Series does Positional {
    has Real @.data = [0.1,0.2,0.3];

    method elems {
        @!data.elems
    }   

    method AT-POS( |p ) is raw {
        @!data.AT-POS( |p )
    }   
}

class DataFrame does Positional {
    has Series @.series;

    method elems { 
        @!series.elems
    }   

    method AT-POS( |p ) is raw { 
        @!series.AT-POS( |p )
    }   
}

my $df = DataFrame.new( series => Series.new xx 3 );

say $df[1].data;            #[0.1 0.2 0.3]
say $df[1][2];              #0.3
say $df[0,1];               #(Series.new(data => $[0.1, 0.2, 0.3]) Series.new(data => $[0.1, 0.2, 0.3]))
say $df[1;2];               #0.3
say $df[1;*];               #(0.1 0.2 0.3)
say $df[*;1];               #(0.2 0.2 0.2)




Answer 1

这个答案只是对@raiph在评论中提出的观点的阐述：

您可以通过使用句柄简化代码

事实上，您可以做到这一点，以至于我认为有必要在没有注释格式限制的代码块中显示它的外观。

使用句柄，您可以将两个类中的每一个从9个非空白行简化为3个：

class Series does Positional {
    has Real @.data handles <elems AT-POS> = [0.1,0.2,0.3];
}

class DataFrame does Positional {
    has Series @.series handles <elems AT-POS>;
}

（或者你甚至可以将每个类放在一行上，如果你按照我想的方式格式化它们的话。）

该代码对问题代码中的say语句产生所有相同的结果。

Answer 2

AT-POS方法只传递整数数组索引。

处理切片的逻辑（使用*、范围、其他可迭代对象、zen切片）位于数组索引运算符中，该运算符被实现为多调度子程序postCirfix：

要使切片工作，必须实现elems以及AT-POS。正在添加：

method elems() { @!data.elems }

是系列和：

method elems() { @!series.elems }

在DataFrame中提供您正在寻找的结果。

如果确实需要不同的切片语义，或者可能实现比标准的更高效的实现，还可以为索引操作符添加多个候选对象（记住标记它们是导出的）。