perl6/raku：如何限制变量中允许的值？

Question

Perl6/Raku

我想创建一个sub，因为只允许将某些值传递给它。不传递允许的值将创建一个checker错误（perl6-c）。

我该怎么做？

非常感谢，-T

你好，Raiph，

在我的WinPopUps模块中，我使用了“在哪里”方法，因为它一目了然地告诉用户允许的值是什么。我喜欢它！这一切都是关于可运维性的！（顺便说一句，下面是你创建的怪物！）

sub WinPopUp( Str $TitleStr, 
              Str $MessageStr,
              Str $Icons where   * ~~ "Exclamation"             |
                                      "Warning"                 |
                                      "Information"             |
                                      "Asterisk"                |
                                      "Question"                |
                                      "Stop"                    |
                                      "Error"                   |
                                      "Hand",
              Str $Buttons where * ~~ "AbortRetryIgnore"        | 
                                      "CancelTryAgainContinue"  |
                                      "Help"                    |
                                      "Ok"                      |
                                      "OkCancel"                |
                                      "RetryCancel"             |
                                      "YesNo"                   |
                                      "YesNoCancel" ) 
              is export( :WinPopUp ) {

谢谢你的帮助-T

如果您想要完整的模块以及在哪里发布，请告诉我

Answer 1

在您的情况下，最好使用枚举：

enum Icons <Exclamation Warning Information>;
sub pop-up( Icons $icon ) { $icon}; 
say pop-up( Information ); # OUTPUT: «Information␤»

但是，由于某种原因，您已经在使用Str，因此使用子集可能更好：

subset Icons of Str where * eq any <Exclamation Warning Information>;
sub pop-up( Icons $icon ) { $icon};
say pop-up( "Information" ); 

这些已经在Holli的回答中提到了，尽管只是“如果你要多次使用它们”。我会定义一个子集，即使你只使用它一个。它更安全，也更清晰，并且可测试。

Answer 2

您可以简单地在值上添加在哪里条件

sub foo( Int $binary where * ~~ 0|1 ) { ... }

在哪里条件可以是任意代码块（甚至是我相信的子代码块）。

如果多次需要该条件，可以创建子集。

subset BinaryInt of Int where * ~~ 0|1;

然后在签名中使用它

sub foo( BinaryInt $binary ) { ... }

请注意，这不仅仅限于子程序签名。约束/条件在任何地方都被强制执行

my BinaryInt $i = 0; 
$i++; 
$i++;
# -> Type check failed in assignment to $i; expected BinaryInt but got Int (2)

您还可以拥有子集的子集：

subset FalseBinaryInt of BinaryInt where not *;
my FalseBinaryInt $i = 0; 
$i++; 
# -> Type check failed in assignment to $i; expected FalseBinaryInt but got Int (1)

编辑：下面的JJ是对的。在这种情况下，枚举很有用。这

sub WinPopUp( Str $TitleStr, 
              Str $MessageStr,
              MessageBoxIcons $Icons where   * ~~ Exclamation |
                                                  Information |
              ...

与类似的枚举配对

enum MessageBoxIcons is export {
    Exclamation => 0x00000030,
    Information => 0x00000040,
    ...
}

保护您免受随机输入错误的影响，因为枚举成员是符号，如果您错拼了一个，编译器将捕获它。此外，您不必查找要输入到MessageBoxW的值（我假设您正在这样做）。

说到MessageBoxW，我会称您的子消息框（在Raku中，我们倾向于仅将CamelCase用于类和类型等）只是为了与MessageBoxW保持一致